The inner loop can be replaced with a hash to change the algorithm from O(N²) to O(N), a major improvement.

my @groups;
my %in_num_groups;
while (@pile) {
    my $item = shift @pile;
    push @{$groups[$in_num_groups{$item}++]}, $item;
}
[download]

I also fixed the needless use of a reference to the array of groups and the inability to store false values in @pile.

Update: For fun, did you know @pile could also be initialized using

@pile = shuffle( (@card) x $n );
[download]

ikegami, your new solution is flawless. Indeed, I had intended to ask for improvements upon my method at the end of my note, but apparently forgot to. Your hash method improves the exact portion of my algorithm that I felt the least confident about. I hate using flags like $found ... too ugly I guess. I knew there surely was a better way, but couldn't quite wrap my mind around it. Thank you very much, as I will be sure to remember this method for future problems.

If you're going to play 52 Perl Pickup, you might as well use CPAN. :-)

use strict;
use warnings;

use Games::Cards;

my $num_decks = 2;

# Create a deck of cards
my $game = Games::Cards::Game->new( {} ); # default game
my $deck = Games::Cards::Deck->new( $game, 'Deck' );
$deck->shuffle;

# Assemble the pile of cards
my @pile;
push( @pile, map { $_->print() } @{ $deck->cards } ) for 1 .. $num_dec
+ks;
my @sorted_pile = sort @pile;

# Compute the number of decks in the pile (pretend we don't know it)
my $num_decks_calc = scalar @sorted_pile / $deck->size;

# Divide the pile into decks
my @decks;
while( @sorted_pile )
{
    foreach my $decknum ( 0 .. $num_decks_calc-1 )
    {
        push( @{ $decks[$decknum] }, pop( @sorted_pile ) );
    }
}

# Print the results
foreach my $decknum ( 0 .. $num_decks_calc-1 )
{
    print join( ' ', @{ $decks[$decknum] } ), "\n\n";
}
[download]

Note: error checking could be added (missing cards, etc).

use strict;
use List::Util qw(shuffle);

# construct a standard deck
my @card;
foreach my $suit (qw(H C S D)) {
    foreach my $value (2..10, qw(J Q K A)) {
        push @card, $value . $suit;
    }
}

# now shuffle us up a pile of cards, perhaps composed of any
# number of decks
my @pile;
my $n = 4;      # number of decks in shuffled pile
push @pile, @card for (1..$n);
@pile = shuffle @pile;


my $decks;
do {
        $decks = grab ( \@pile ); # split the pile into $n decks
        @pile = lookup( $decks ); # Look if we got it right..
} while ( @pile > 0 );
        

print "Got it!\n";

for my $a (0..$n){
        print "$_ " foreach ( @{$decks->{$a}} );
        print "\n\n";
}
# Exits here.. happily


sub grab{
        my $pile = shift;

        my $decks;
        # Grab the cards
        foreach my $card (@{$pile}){
                push @{$decks->{int(rand($n))}}, $card;
        }
        return $decks;
}

sub lookup{
        my $decks = shift;
        
        for my $a (0..$n-1) {
                my %cards; 
                foreach my $card ( @{$decks->{$a}} ){
                        if ( defined( $cards{$card} ) ){
                                damnit( $decks );
                                return throw ( $decks );
                        } else {
                                $cards{$card} = 1; # Remember this. An
+d dont forget it!
                        }
                }
        }
}

sub damnit{
        my $decks = shift;

        print "Damnit!!!\n";
        for my $a (0..$n){
                print "$_ " foreach ( @{$decks->{$a}} );
                print "\n\n";
        }
}

sub throw{
        my $decks = shift;

        my @pile;
        foreach ( values %{$decks} ){
                push @pile, @{$_};
        }
        return shuffle( @pile );            
}
[download]

use List::Util qw(shuffle);

use strict;

# Ordered least to greatest
my @suit = qw(C D H S);
my @rank = ( 2 .. 10, qw(J Q K A) );

# Construct a standard deck
my @card = map {
    my $suit = $_;
    map { "$_$suit" } @rank
} @suit;

# Shuffle 4 piles of cards.
my @pile = shuffle( (@card) x 4 );

print "Pile\n\t@pile\n\n";

# Sort
my %ord_suit = map { $suit[$_] => $_ } ( 0 .. $#suit );
my %ord_rank = map { $rank[$_] => $_ } ( 0 .. $#rank );

my @pile_sorted = map { $_->[0] } sort {
         $ord_suit{ $a->[1][1] } <=> $ord_suit{ $b->[1][1] }
      || $ord_rank{ $a->[1][0] } <=> $ord_rank{ $b->[1][0] }
} map { [ $_, [m/(.*)(.)/] ] } @pile;

# Group Cards into Decks
my @deck;
my $lastcard = '';
my $index;

for my $card (@pile_sorted) {
    if ( $card ne $lastcard ) {
        $index = 0;
    }
    else {
        $index++;
    }

    push @{ $deck[$index] }, $card;

    $lastcard = $card;
}

print "Decks\n";
foreach (@deck) {
    print "\t@$_\n";
}
[download]

And if you want to do this more generically:

Define an unique order for each object. In this instance that happens to just be the card's value. Then create a list of hashes where a card is only added if one of the same order does not exist.

use List::Util qw(shuffle first);

use strict;

# Ordered least to greatest
my @suit = qw(C D H S);
my @rank = (2..10, qw(J Q K A));

# Construct a standard deck
my @card = map {
    my $suit = $_;
    map {"$_$suit"} @rank
} @suit;

# Shuffle 4 piles of cards.
my @pile = shuffle( (@card) x 4 );

print "Pile\n\t@pile\n\n";

# Group Cards into Decks
my @deck;

for my $card (@pile) {
    # Order of Object
    my $ord = $card;
    
    my $deck = first {! exists $_->{$ord}} @deck;
    
    # Start new deck
    if (! $deck) {
        $deck = {};
        push @deck, $deck;
    }
    
    $deck->{$ord} = $card;
    
}

# Results:
print "Decks:\n";
for my $deck (@deck) {
    print "\t" . join(' ', values %$deck) . "\n";
}
[download]

When you view the results, you'll notice that each of the "decks" appear to be near identical. This is because of the internal implementation of hashes and the way that elements are assigned a place in the hash.

- Miller

My previous post was a non-sequitur, sorry. It would be easier if the dealer wasn't colour-blind. We could factor in the backs.

#!/usr/bin/perl -w
# Re-sorting a pile of four decks. Unfazed by missing cards.
# Using tr to avoid the unfathomable card-sort map.

# Mock names for easy sorting
my @suit = qw(f g h i);
my @rank = (2..9, qw(a b c d e));
my @pile= ();

sub shuffle { 
    for (my $i = $#_ ; $i > 0 ; $i--) {
        @_[$_, $i] = @_[$i, $_] for rand $i+1
    } return @_;
}
sub readable {
    my $string = join(" ", @_);
    $string =~ tr/abcdefghi/TJQKACDHS/;
    return $string;
}
sub separate {
    my @cards = sort @_;
    my @box = (); my $deck = 0; my $prevcard = "";
    for my $card (@cards) {
        if ($card ne $prevcard) {$deck = 0};
        push @{$box[$deck++]}, $card;
        $prevcard = $card;
    }
    return @box;
}

for (1..4) {
    push (@pile, (map {$rank = $_; map {"$_$rank"} @suit} @rank));
}
shuffle @pile;
print "\nFour decks shuffled together\n";
print (readable @pile);
my @decks = separate @pile;
print "\n\nFour decks separated\n";
foreach (@decks) {
    print (readable @$_);
    print "\n";
}
[download]

Which can be whittled down to a more useful PNB dealer which would normally be written to a file. I did it to feed the the GIB command-line bridge engine.

 
#!/usr/bin/perl 
## Dealing cards in PBN (Portable Bridge Notation)
## Using tr to avoid the awesome card-sort map

## mock names for easy sorting
my @suit = qw(f g h i);
my @rank = (2..9, qw(a b c d e));
my @seps = qw(g. h. i.);

sub shuffle { 
    for (my $i = $#_ ; $i > 0 ; $i--) {
    @_[$_, $i] = @_[$i, $_] for rand $i+1
    } return @_;
}

## reformats one hand at a time
sub pbnFormat {
    push (@_, @seps) ;
    local $string = join(``, sort{$b cmp $a}@_);
    $string =~ tr/abcdefghi/TJQKA/d;
    return $string;
}

my @deck = shuffle(map{$rank=$_; map{"$_$rank"}@suit}@rank);

for(1..4) {
    print pbnFormat splice @deck,0,13;
    print "\n";
}
[download]