Very Simple Conversion of Gregorian to Julian Calendar

Aim9b has asked for the wisdom of the Perl Monks concerning the following question:

I need to convert the mm/dd ranges such as 0112 - 0402 into the filenames testnnn.txt where nnn = 012 for jan 12th, thru 092 for April 2nd, etc. Year is irrelevant, & leap year can be hard coded in the shortterm, since this will not be used past 2020. I've digressed to the following code, & it appears to work...

sub conv2jul {
   my $moda=shift;
   my @Days = (0,31,28,31,30,31,30,31,31,30,31,30,31);
   if ($leapyear) { $Days [2] = 29; }
   my $jul = 0;  my $i = 0;
   my $mo = substr($moda,0,2);
   my $da = substr($moda,2,2);
   if (($mo <= 0) || ($mo > 12)) { return "000"; }
   if (($da <= 0) || ($da > 31)) { return "000"; }
   for ($i = 0;$i < $mo;$i++) { $jul += $Days[$i]; }
   $jul += $da;
   return $jul;
}
[download]

But I started with this & I'm curious as to why it doesn't work...

sub conv2jul {
   my $moda=shift;
   my @Days = (0,31,28,31,30,31,30,31,31,30,31,30,31);
   if ($leapyear) { $Days [2] = 29; }
   my $jul = 0;  my $i = 0;
   my $mo = substr($moda,0,2);
   my $da = substr($moda,2,2);
   if (($mo <= 0) || ($mo > 12)) { return "000"; }
   if (($da <= 0) || ($da > 31)) { return "000"; }
   $jul += ($Days[$mo..$mo-1]) + $da;     # his is the only diff
   return $jul;
}
[download]

I've tried several variation of this syntax, & I always get 0 returned in $jul. Is the range op just not usable in this scenario? More likely I've just hosed it beyond belief ;-) If you can see what I'm trying to accomplish & can offer any enlightenment I'd be very thankful.

Comment on Very Simple Conversion of Gregorian to Julian Calendar Select or Download Code

Replies are listed 'Best First'.
Re: Very Simple Conversion of Gregorian to Julian Calendar by almut (Canon) on Aug 22, 2007 at 13:01 UTC
There are also a couple of modules out there on CPAN for this, for example `Time::JulianDay`. You could use it like this (which should also handle leap years correctly): `use Time::JulianDay; sub conv2jul { my ($moda, $year) = @_; my ($mon, $day) = unpack "A2A2", $moda; return julian_day($year, $mon, $day) - julian_day($year, 1, 0); } for my $year qw(2000 2007) { print "$year:\n"; for my $moda qw(0112 0402 1231) { my $jd = conv2jul($moda, $year); printf " %s --> %03s\n", $moda, $jd; } }` [download] would print: `2000: (leap year) 0112 --> 012 0402 --> 093 1231 --> 366 2007: 0112 --> 012 0402 --> 092 1231 --> 365` [download]	[reply] [d/l] [select]
Re: Very Simple Conversion of Gregorian to Julian Calendar by moritz (Cardinal) on Aug 22, 2007 at 12:15 UTC
What do you want to do here? The idea is to add the number of days per month to `$jul` - but what you are trying is neither a loop nor a sum, but some kind of array slice (that would be written as `@Days[0 .. $mo]`). Maybe you meant something like this: `use List::Util qw(sum); ... $jul = sum(@Days[0..$mo]) + $da;` [download] By the way please try to write in proper english words, we all try (and we're not all native speakers) Perl 6 in German -- Difficult Sudoku	[reply] [d/l] [select]
Re: Very Simple Conversion of Gregorian to Julian Calendar by FunkyMonk (Bishop) on Aug 22, 2007 at 12:47 UTC
You just can't do it - it doesn't make sense in Perl. The nearest thing to do what you intend (without using any modules) needs a loop: `my $jul = $da; $jul += $_ for @Days[0..$mo-1];` [download] `@ARRAY[LIST]` is known as an array slice. It returns a list of elements of `@ARRAY`. You can also slice a hash. See Slices for the details.	[reply] [d/l] [select]
Re: Very Simple Conversion of Gregorian to Julian Calendar by Fletch (Bishop) on Aug 22, 2007 at 12:59 UTC
The Julian day or Julian day number (JDN) is the integer number of days that have elapsed since the initial epoch defined as noon Universal Time (UT) Monday, January 1, 4713 BC in the proleptic Julian calendar. (...) The use of Julian date to refer to the day-of-year (ordinal date) is usually considered to be incorrect, however it is widely used that way in the earth sciences and computer programming. </pedant>	[reply]