There are a couple of issues, here. The first is that you always want to use

use warnings;
use strict;
[download]

Next, you're using a scalar as the argument to your 'sort' routine. 'sort' is going to want an array and it'll return the sorted array.

Next, you should consider using Date::Simple or (for more complex stuff) DateTime. To do this, you first install the module, then something like:

use DateTime;

my @dates;
while(<...>)
{
  my $date = DateTime->new(...);
  push @dates, $date;
}

my @sorted = sort @dates;
[download]

Hope that helps!

Update: fixed a typo

Regardless, I see a few problems, in addition to the sort issue mentioned by others. You would have gotten warning messages had you used the strictures:

use warnings;
use strict;
[download]

You would have been warned about month_from being a bareword and the Useless use of sort in void context. Also, use diagnostics can be used to get more verbose warning messages.

Another problem is that you should always check if a regex match succeeded before using $1, $2, etc.

[matt@test ~/testdir]$ stat -c %Y AMR.xml
1206990376
[download]

#!/usr/bin/perl

use strict;
use POSIX qw(strftime);

my $dir = '/your/dir';

opendir DIR, $dir or die $!;
my @files = grep { /\.xml$/ && ! /^\./ } readdir DIR;
closedir DIR;

my %ds;

for my $file (@files) {
    my $mtime = (stat("/your/dir/$file"))[9];

    $ds{$file} = $mtime;
}

for my $sorted_file (sort { $ds{$a} <=> $ds{$b} } keys %ds) {
    my $file_date = strftime("%Y-%m-%d", localtime($ds{$sorted_file}))
+;
    my $file_time = strftime("%H:%M:%S", localtime($ds{$sorted_file}))
+;
    print qq[<option value="$sorted_file">$file_date $file_time</optio
+n>\n];
}
[download]

Good points.

The only problem with the mtime stat on a file is that it may or may not have anything to do with the time encoded in the filename that the OP was interested in. So that may or may not be helpful for the OP.

But if it turns out to, indeed, be applicable, then, to me, it sure would simplify the code and make the sorting even more compact.

ack Albuquerque, NM

$ls *.xml
123_20070303_REFNUM.xml
123_20071225_REFNUM.xml
123_20080101_REFNUM.xml
923_20070227_REFNUM.xml
[download]

#!/usr/bin/perl 
use strict;
use warnings;
use Date::Simple (':all');
use Data::Dumper;

my $dir = q{/home/LarryTheLobster/};

opendir(DIR, $dir) or die $!; 

my @xml_files =
sort { d8( (split /_/, $a)[1] ) cmp  d8( (split /_/, $b)[1] ) } 
grep { -f and /[.]xml\z/ } readdir DIR;

closedir DIR;

print Dumper \@xml_files;
[download]

Output:
$VAR1 = [
          '923_20070227_REFNUM.xml',
          '123_20070303_REFNUM.xml',
          '123_20071225_REFNUM.xml',
          '123_20080101_REFNUM.xml'
        ];
[download]

hth,
PooLpi

++ for seeing that you don't need a regex to get hold of the date part.

But why do you transform the date into a Date::Simple object in order to sort it? A date in the yyyymmdd format can be sorted numerically without any further ado.

And of course, this kind of thing just screams for the Schwartzian Transform:

use strict;
use warnings;
use Data::Dumper;

my @xml_files = map { $_->[0] }
                sort { $a->[1] <=> $b->[1] }
                map { [$_, (split /_/, $_)[1]] }
                <DATA>;

print Dumper \@xml_files;

__DATA__
123_20070303_REFNUM.xml
123_20071225_REFNUM.xml
123_20080101_REFNUM.xml
923_20070227_REFNUM.xml
[download]

If there are only a few files to be sorted, it is of course overkill, but once the number of files increases the fact that you only have to do the split once for each file pays of.

CountZero

A program should be light and agile, its subroutines connected like a string of pearls. The spirit and intent of the program should be retained throughout. There should be neither too little or too much, neither needless loops nor useless variables, neither lack of structure nor overwhelming rigidity." - The Tao of Programming, 4.1 - Geoffrey James

What part of the documentation for sort lead you to believe that calling it with a single element from what you wanted sorted would be at all fruitful?

The part that the code is going trough a while loop.