Re: The Dates Sorting!

$ls *.xml
123_20070303_REFNUM.xml
123_20071225_REFNUM.xml
123_20080101_REFNUM.xml
923_20070227_REFNUM.xml
[download]

#!/usr/bin/perl 
use strict;
use warnings;
use Date::Simple (':all');
use Data::Dumper;

my $dir = q{/home/LarryTheLobster/};

opendir(DIR, $dir) or die $!; 

my @xml_files =
sort { d8( (split /_/, $a)[1] ) cmp  d8( (split /_/, $b)[1] ) } 
grep { -f and /[.]xml\z/ } readdir DIR;

closedir DIR;

print Dumper \@xml_files;
[download]

Output:
$VAR1 = [
          '923_20070227_REFNUM.xml',
          '123_20070303_REFNUM.xml',
          '123_20071225_REFNUM.xml',
          '123_20080101_REFNUM.xml'
        ];
[download]

hth,
PooLpi

'Ebry haffa hoe hab im tik a bush'. Jamaican proverb

Comment on Re: The Dates Sorting! Select or Download Code

Replies are listed 'Best First'.
Re^2: The Dates Sorting! by CountZero (Bishop) on Apr 01, 2008 at 19:54 UTC
++ for seeing that you don't need a regex to get hold of the date part. But why do you transform the date into a Date::Simple object in order to sort it? A date in the yyyymmdd format can be sorted numerically without any further ado. And of course, this kind of thing just screams for the Schwartzian Transform: `use strict; use warnings; use Data::Dumper; my @xml_files = map { $_->[0] } sort { $a->[1] <=> $b->[1] } map { [$_, (split /_/, $_)[1]] } <DATA>; print Dumper \@xml_files; __DATA__ 123_20070303_REFNUM.xml 123_20071225_REFNUM.xml 123_20080101_REFNUM.xml 923_20070227_REFNUM.xml` [download] If there are only a few files to be sorted, it is of course overkill, but once the number of files increases the fact that you only have to do the `split` once for each file pays of. CountZero A program should be light and agile, its subroutines connected like a string of pearls. The spirit and intent of the program should be retained throughout. There should be neither too little or too much, neither needless loops nor useless variables, neither lack of structure nor overwhelming rigidity." - The Tao of Programming, 4.1 - Geoffrey James	[reply] [d/l] [select]

Replies are listed 'Best First'.

Re^2: The Dates Sorting!
by CountZero (Bishop) on Apr 01, 2008 at 19:54 UTC

But why do you transform the date into a Date::Simple object in order to sort it? A date in the yyyymmdd format can be sorted numerically without any further ado.

And of course, this kind of thing just screams for the Schwartzian Transform:

use strict;
use warnings;
use Data::Dumper;

my @xml_files = map { $_->[0] }
                sort { $a->[1] <=> $b->[1] }
                map { [$_, (split /_/, $_)[1]] }
                <DATA>;

print Dumper \@xml_files;

__DATA__
123_20070303_REFNUM.xml
123_20071225_REFNUM.xml
123_20080101_REFNUM.xml
923_20070227_REFNUM.xml
[download]

If there are only a few files to be sorted, it is of course overkill, but once the number of files increases the fact that you only have to do the split once for each file pays of.

CountZero

A program should be light and agile, its subroutines connected like a string of pearls. The spirit and intent of the program should be retained throughout. There should be neither too little or too much, neither needless loops nor useless variables, neither lack of structure nor overwhelming rigidity." - The Tao of Programming, 4.1 - Geoffrey James

[reply]
[d/l]
[select]