in reply to Re: IPC via named pipes, losing some messages
in thread IPC via named pipes, losing some messages

Thanks everyone for your help. I finally cracked it yesterday. The trick is to open the pipe for read/write, bypass perlio and have a blocking read. The code below shows how it's done. I could possibly have moved to sockets, but pipes are as old as the hills so it should be possible to use them and on top of that the writer could be a bash script. Having said that, I did find out how to have bash write to a socket... 
# Non blocking open
open (FH, "+<", $config->{'pipe'} ) || die "Unable to open $config->{'
+pipe'}";

my $rin = '';
my $rout = '';
vec( $rin, fileno(FH), 1) = 1; # No, I have no idea either

# Loop forever.
while (1) {

    # Wait for the pipe to change status
    my $nfound = select( $rout = $rin, undef, undef, undef ); # blocki
+ng select

    my $data;
    # Non blocking select only returns a value while there is somethin
+g in the pipe
    while ( select( $rout = $rin, undef, undef, 0 ) ) {
        sysread FH, my $buf, 2048;
        $data .= $buf;
    }

    Log( { logfile => $log_file, text => 'trace: START: '. ( $data || 
+'$data no val' ) }) if TRACE;

    # 9/4/8 A request is C,DIR,1ROSE
    # Multiple requests can come through on one read ie C,FOO,1ROSEC,B
+AR,1ROSE
    for ( split /ROSE/, $data ? $data : '' ) {
        if ( /^RELOAD/ ) {
            # Reread the config file
            Log({logfile=>$log_file, text=> qq{RELOAD: Reloading confi
+g}});
            load_config();
        }
        else {
            process_input( { data => $_ } ) if $_;
        }
    }

} # while 1

[download]

Replies are listed 'Best First'.
Re^3: IPC via named pipes, losing some messages
by ikegami (Patriarch) on Apr 15, 2008 at 21:31 UTC

    "ROSE" has got to be the weirdest line ending I've ever seen.

    I took the liberty of cleaning up your code a bit.

    • I fixed a bug where a single message could be considered two.
    • I eliminated the select which needlessly served to empty the pipe.
    • I replaced split since you have a record terminator rather than a record separator. 
    # Non blocking open
open (FH, "+<", $config->{'pipe'} ) || die "Unable to open $config->{'
+pipe'}";

my $buf = '';

# Loop forever.
while (1) {
    my $rv = sysread( FH, $buf, 2048, length($buf) );
    die("Error reading from pipe: $!\n") if !defined($rv);

    # 9/4/8 A request is C,DIR,1ROSE
    # Multiple requests can come through on one read ie C,FOO,1ROSEC,B
+AR,1ROSE
    while ($buf =~ s/(.*?ROSE)//s) {
       my $rec = $1;
       Log( { logfile => $log_file, text => "trace: START: $rec" }) if
+ TRACE;

        if ( $rec =~ /^RELOAD,/ ) {
            # Reread the config file
            Log({logfile=>$log_file, text=> qq{RELOAD: Reloading confi
+g}});
            load_config();
        }
        else {
            process_input( { data => $rec } );
        }
    }

} # while 1

    [download]
[reply]
[d/l]
[select]
      Thanks for that. I'm going to test it next week. I would do it sooner but I'm off tomorrow and I don't like sending software live before I'm away. It tends to generate tedious wtf have you done now telephone calls... Could you explain what you mean in your bullet points, 1 and 3 please? John
[reply]

        • Re: I fixed a bug where a single message could be considered two.

          If "C,DIR,1ROSE" is sent over the pipe, the reader might only read "C,DI" which you were treating as an entire message. Then you would proceed to treat "R,1ROSE" as a second message. I fixed this keeping message fragments in the buffer and appending to the unprocessed data in the buffer instead of using a fresh buffer every pass.

          The bug in question might not actually exist due to the select, but it's hard to be sure and would be OS-dependent.

        • Re: I replaced split since you have a record terminator rather than a record separator.

          split is useful when your data looks like "ITEM SEP ITEM SEP ITEM". It doesn't make much sense when your data looks like "ITEM TERM ITEM TERM ITEM TERM", as is the case for you.

[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom