map

my @minutes_list = grep $_ != 0, map $_ * 10, @ratio_list;
[download]

or

my @minutes_list = map $_*10 || (), @ratio_list;
[download]

(There's nothing at all wrong with your solution. I just wanted to point out an often overlooked feature of map ... that is, it can return a list shorter than the input list, if you have the expression evaluate to the empty list for the elements to be dropped.)

use strict;
use warnings;

my $max = $ARGV[0];
my @ratio_list = (0,1..$max); 
my @minutes_list = map {$_ * 10} grep {$_ != 0} @ratio_list;
print "@minutes_list\n";
[download]

prints:

10 20 30 40 50
[download]

pugs> my @nums = 1, 2, 4, 5, 0, 8;
pugs> grep { $_ }, 10 >>*<< @nums;
(10, 20, 40, 50, 80)
[download]

(I think that standard perl 6 would use 10 * << @nums instead, only the side where a dimension is folded gets the hyper op. But pugs is a bit out of date).

Likewise you can add or multiply arrays piecewise:

pugs> <1 2 3> »+« <0 1 0>
(1.0, 3.0, 3.0)
[download]

( » is an alias for >>, « an alias for <<)

And, very powerful as well, the reduce operator:

pugs> [+] <1 2 3> 
6.0
[download]

use strict;
use warnings;

my $max = shift;
my @rl  = ( 0 .. $max );
my @ml  =
   map  { $_ * 10 }
   grep { $_ }
   @rl;

print qq{$_\n} for @ml;
[download]

Cheers,

JohnGG

#!/usr/bin/perl
use strict;
use warnings;

use PDL;

my $max = $ARGV[0];

my $ratio_list = pdl (0..$max);

my $minutes_list = 10 * $ratio_list;
[download]

perl -MPDL -e '$n=shift; print +(sequence($n)+1)*$n'

Turning the resulting ndarray into a flattened Perl list (with the list method) or structured Perl array (with the unpdl method) is left as an exercise for the reader.

Kind-of seems to me like pounding a thumbtack with a sledgehammer. Of course, TIMTOWTDI

--
Wade

Sure, but steph_bow asked for simple. It was simple to write and it's simple to read and it DWIM.

for (0..$#ratio_list){
    $ratio_list[$_]  *= 10;
}
[download]

This does not filter values that are 0, but does multiply every element of the array by 10. Not sure if you really want to filter zeroes.

This is just slightly more efficient (at least in terms of keystrokes if not execution time):

for (@ratio_list) { $_ *= 10 }
[download]

If you wanted to simultaneously create @minutes_list, you can use:

for (@ratio_list) { ($_ *= 10) && push(@minutes_list, $_) }
[download]

for (@ratio_list) { $_ *= 10 }

If you're going to do that, why not get rid of useless punctuation altogether?

$_ *= 10 for @ratio_list;