Have a look at the List::Util core module, particularly the max() routine. Also be aware the array subscripts are zero-based so your

...
    my $pos = $data[1];
    my $cons1 = $data[2];
    my $cons2 = $data[3];
    my $cons3 = $data[4];
    my $cons4 = $data[5];
    my $cons5 = $data[6];
...
[download]

will be pointing one element too far to the right. You can also do that in one fell swoop.

while( <FILE> )
{
    my( $pos, $cons1, $cons2, $cons3, $cons4, $cons5 ) = split;
...
[download]

The default action for split is to split $_ on whitespace.

I hope this is helpful.

Cheers,

JohnGG

Close.

    if($count < 5)
    {
        ...
    }
    else
    {
        print "$pos ... \n";
        $count = 0;
        @data  = ();
    }
[download]

but you would need to reset $largest_cons<n> too, depending on your requirements.

Some points:

• you use English, FileHandle and Exception, but then you don't make use of them. Why?
• Why those $largest_cons<number> variables? Wherever you are inclined to number your variables, you really want an array
• at open(FILE, "$input") use three-argument open
• at open(FILE, "$input") - useless use of quotes

You could also use $. (see perlvar) in a flip-flop (".." - see perlop):

#!/usr/bin/perl -w

use strict;
use warnings;

my $input = shift;

#open FILE, '<', "$input" or die "ERROR: Unable to open input file: $!
+\n";

my @largest_cons = (0) x 6; # inhibit "uninitialized" warnings

while (<DATA>)
{
    my @data = split;

#    if ( 1 .. 5 )    # see update below
#    {
        $largest_cons[0] = $data[0]
          if $. == 1;
        for (1..$#data)
        {
            $largest_cons[$_] = $data[$_]
              if $data[$_] > $largest_cons[$_];
        }
        if ($. == 5) 
        {
            $largest_cons[0] .= '-' . $data[0];
            print "@largest_cons\n";
            $. = 0;
            @largest_cons = (0) x 6;
        }
#    }
}
[download]

Note that starting with 1, you end at 1-5 .. 11-15 rather than 10-14. For that you need a row 0.

Update: on a second look at the code I've posted, the flip-flop-business doesn't make sense here... ;)

use warnings;
use strict;

use List::Util qw(max);

my @window;

while (<DATA>)
{
    chomp();

    # create sliding window
    push(@window, [ (split) ]);
    shift(@window) if $. > 5;

    # print range
    print $window[0][0], "-", $window[-1][0];

    # print maximums
    for my $i (1 .. 5)
    {
        print " ", max(map { $_->[$i] } @window);
    }

    print "\n";
}

__END__
 1   0    0.00       0    0    0   
 2   0    0.00       0    0    0   
 3   0    0.08       0    0    0   
 4   0    0.05       0    0    0   
 5   0    0.08       0    0    0   
 6   0    0.05       0    0.12    0   
 7   0    0.05       0    0.12    0   
 8   0    0.04       0    0.15    0   
 9   0.07    0.07       0    0.15    0.18   
 10   0.29    0.04       0.32    0.32    0.19   
 11   0.46    0.05       0.42    0.30    0.21   
 12   0.45    0.07       0.35    0.29    0.41   
 13   0.57    0.07       0.42    0.00    0.47   
 14   0.46    0.04       0.62    0.00    0.58   
 15   0.39    0.05       0.41    0.00    0.37
[download]

1-1 0 0.00 0 0 0
1-2 0 0.00 0 0 0
1-3 0 0.08 0 0 0
1-4 0 0.08 0 0 0
1-5 0 0.08 0 0 0
2-6 0 0.08 0 0.12 0
3-7 0 0.08 0 0.12 0
4-8 0 0.08 0 0.15 0
5-9 0.07 0.08 0 0.15 0.18
6-10 0.29 0.07 0.32 0.32 0.19
7-11 0.46 0.07 0.42 0.32 0.21
8-12 0.46 0.07 0.42 0.32 0.41
9-13 0.57 0.07 0.42 0.32 0.47
10-14 0.57 0.07 0.62 0.32 0.58
11-15 0.57 0.07 0.62 0.30 0.58
[download]

hints below

...
open FILE, "<$ARGV[0]";
@data_records=<FILE>;
for ($x=0;$x<@data_records;$x++){
   for ($index=$x; $index<($x+5);$index++){
      @record=split(/\s+/, $data_records[$index]);
      for($index=1;$index<@record;$index++){
         $max[$index]=$record[$index] if $max[$index]<$record[$index];
      }
   }
   print "$ARGV[0]-",$ARGV[0]+5,"@max\n";
}
[download]