my $line = <FILE>;
$line =~ s/\(|\)//g;
my @numbers = split /\,|\;/, $line;
[download]

It'd make sense to swap to a different delimiter to reduce the LTS, of course.

Update: Of course there's no need to use split at all. The one liner:

my($test1,$test2,@numbers) = (my $line = <FILE>) =~ /[0-9.]+/g;

There is definitely no need for all of those splits. If you want an array that contains all numbers, e.g. you want to replace a single array element "(0,670)" with two array elements one for each number. You could do the following:

use strict;
use warnings;

while (my $line = <DATA>) {

  #remove all whitespace
  $line =~ s/\s//g;

  #split line
  my @aFields = split(/;/, $line);

  #remove parenthesised field
  my $sFld1 = shift @aFields;

  #convert parenthesized field to numbers
  my ($sNoParens) = ($sFld1 =~ /^\(([^)]*)\)$/);
  my @aSubFields = split(/,/, $sNoParens);

  # if you want to make sure there are only N
  # numbers, do your checks here.

  #put the numbers where fld0 was originally
  unshift @aFields, @aSubFields;

  #print the result
  print "<@aFields>\n";
}

__DATA__
( 0, 670); 3.2; 7.8; 9.4; 10.2; 12.6;
[download]

See shift and unshift for more information.

Best, beth

You could use a regexp to get the values:

($test1,$test2)= $split1[0]=~/\(\s*(\d+),\s*(\d+)/;
[download]

It looks more complicated than it is because '(' has to be escaped when you want to search for it in a regular expression. The other parens in the search pattern are used as capture markers, anything between them is given back as a list in list context

And yes, you can use the numbers to perform any operations, any string that looks like a number can be used as a number

UPDATE: corrected the array access

YAWTDI

$line =~ s/[(),;]//g;
my @split1 = split " ", $line;
[download]

And yes, once you have these split up, they can be used in numeric calculations.

Just a quick note, when you're referring to a single element of an array, use $split1[0] rather than @split1[0]. See "perldoc -q @" and look at the answer for "What is the difference between $array[1] and @array[1]?"

You may want something like this:

$ perl -le'
my $line = "(  0,  670); 3.2; 7.8; 9.4; 10.2; 12.6;";
my @split1 = $line =~ /\d+(?:\.\d+)?/g;
print for @split1;
'
0
670
3.2
7.8
9.4
10.2
12.6
[download]

use Regexp::Common;

my @split = $line =~ /$RE{num}{real}/g;
[download]

There is no need for regex. It only takes a tr///d and a simple split():

while ( my $line = <DATA> ) {
  chomp $line;
  
  # backup of line, in case we need original version later
  my $line_copy = $line;

  # transliterate ',' into ';' remove '(', ')' and space(0x20)
  $line =~ tr/,() /;/d;

  # split at ';'
  my ( $first, $second, @rest ) = split /;/, $line;

  # do your work
}
[download]

Excellent, works exactly how I wanted it to and makes the code nice and self explanatory, also got me to read about transliteration, so thanks for that and for all the other answers!

TIMTOWTDI (where the it in question is the extraction of the numbers in order from the line) -

 perl -MData::Dumper -e 'print Dumper grep length $_, split /[^\d\.]+/
+, "(  0,  670); 3.2; 7.8; 9.4; 10.2; 12.6;"'
[download]

$VAR1 = '0';
$VAR2 = '670';
$VAR3 = '3.2';
$VAR4 = '7.8';
$VAR5 = '9.4';
$VAR6 = '10.2';
$VAR7 = '12.6';
[download]