I'm not to sure about your spec but if it is get the text within bold tags that are within td tags then something like this will get you started.

#!/usr/bin/perl

use warnings;
use strict;
use HTML::TokeParser::Simple;

my $html = do{local $/;<DATA>};
my $p = HTML::TokeParser::Simple->new(string => $html);

my ($in_td, $in_b);
while (my $t = $p->get_token) {
  $in_td++, next if $t->is_start_tag(q{td});
  $in_b++,  next if $in_td and $t->is_start_tag(q{b});
  next unless $in_td and $in_b;
  if ($t->is_text){
    print $t->as_is, qq{\n};
    $in_td = 0;
    $in_b = 0;
  }
}

__DATA__
<TR class="violet3">
  <TD ><B>hsa-miR-107</B></TD>
  <TD >17.1922</TD>
  <TD >-21.47</TD>
  <TD >2.119850e-02</TD>
  <TD >2.097540e-02</TD>
  <TD >6.191350e-04</TD>
  <TD >106</TD>
  <TD >127</TD>
  <TD ><pre><FONT COLOR="#FFFFFF">a</FONT><FONT COLOR="#FFFFFF">c</FON
+T><FONT COLOR="#FFFFFF">u</FONT><FONT></FONT>
</TR>
<TR class="violet2">
  <TD ><B>hsa-miR-103</B></TD>
  <TD >17.1922</TD>
<TR class="violet3">
  <TD ><B>hsa-miR-651</B></TD>
  </TR>
<TR class="violet2">
  <TD ><B>hsa-miR-320</B></TD>
[download]

hsa-miR-107
hsa-miR-103
hsa-miR-651
hsa-miR-320
[download]

It is not entirely clear what you want to do, but if you need to extract the values of the first cell in TRs which class name starts with 'violet', then you could use HTML::TreeBuilder::XPath:

#!/usr/bin/perl

use strict;
use warnings;
 
use HTML::TreeBuilder::XPath;
my $tree = HTML::TreeBuilder::XPath->new; # empty tree
$tree->parse_file( 'myfile.html');

my @values= $tree->findvalues( '//tr[@class=~/^violet[0-9]/]/td[1]');

foreach my $value (@values) { print $value, "\n"; }
[download]

Now I paste my code....the one I used and the error message...I would'nt past it before for not looking so stupid as I am....:-(

#!/usr/local/bin/perl
use strict;
use warnings;
use LWP::Simple;


my $url3="http://microrna.sanger.ac.uk/cgi-bin/targets/v5/detail_view.
+pl?transcript_id=ENST00000226253";
my $content=get $url3;

use HTML::TreeBuilder;
my $tree = HTML::TreeBuilder->new;
$tree->parse_file($content);
$tree->delete;
use HTML::Element;


my @elements = my $element->find('b',);
my @anchors = $element->look_down('_tag' => 'b');

print "@elements\n";
[download]

and now the error.... Can't call method "find" on an undefined value at test.pl line 17......I don't now how to select the string between "b" and "/b" because I don't actually know html......and I don't understand the synthax...

Nearly! :-)

!/usr/bin/perl

use warnings;
use strict;
use HTML::TreeBuilder;

my $html = do{local $/;<DATA>};
my $p = HTML::TreeBuilder->new;
$p->parse_content($html); # parse_content if you have a string

my @tds = $p->look_down(_tag => q{td}); # get a list of all the td tag
+s
for my $td (@tds){
  my $bold = $td->look_down(_tag => q{b}); # look for a bold tag
  if ($bold){
    print $bold->as_text, qq{\n}; # if there is one print the text
  }
}
$p->delete; # when you've finished with it
[download]

Aside from understanding wfsp's solution, definitely check out the Documentation section of HTML-Tree for some articles for relative beginners that certainly aided my understanding of OO modules, HTML, tree structures, and parsing.