First of call, calling ->content is pretty much always a bug. And it is here. You want

print $response->decoded_content();
[download]

or

print $response->decoded_content( charset => 'none' );
[download]

The latter won't undo the character encoding for XML and HTML docs.

HOWEVER, I cannot print this to a file.

That's unfortunate.

I am inclined to believe I am missing something.

Probably, but it's hard to tell what you're missing without knowing what you have.

I am able to print the content to stdout

that does not work since nothing is going to stdout

uh, which one is it?

There's no reason you can't print the content to a file. Clearly something else is going on, probably with your popen business. Without some example code, there's little we can do.

Can you distill your code down to a small example that demonstrates the problem? I bet you'll find the cause of the problem while trying to do so.

All, Here is my code:

#!/usr/bin/perl

use strict;
use LWP::UserAgent;

my $ua;
my $req;
my $res;

$ua = new LWP::UserAgent;
$ua->agent("AgentName/0.1 " . $ua->agent);

#REQUEST

$req = HTTP::Request->new(GET =>'http://SOMEURLHERE');

#PASS REQUEST

$res = $ua->request($req);

#GET RESULTS


if($res->is_success)
{
   print $res->content;
}
else
{
   print "No response\n";
   print $res->status_line . "\n";
}
[download]

Now the above code will print out just fine. However, if I try to add something like the following into the above code:

open(MYFILE, '/tmp/data.txt');
print MYFILE $res->content;
close(MYFILE);
[download]

Or if I first assign the response data to a scalar and then do it:

my $returnData = $res->content;
open(MYFILE, '/tmp/data.txt');
print MYFILE $returnData;
close(MYFILE);
[download]

The file "/tmp/data.txt" is an empty file (although I didn't check it with "ls -l" which I probably should have). I just did a "cat" on the file and it was blank. I am also pretty sure that the popen command is not affecting things because if I print out a simple string from the same Perl script, that gets captured with popen. It has something to do with this HTTP::Response module.

Extra tidbits:

• If something isn't working as expected, one should start by checking what error occured! open, print and close all indicate if they were successful, and if not, why they weren't.

• Declaring variables before they are used just introduces the possibility of errors. Instead of

  my $x;
  ...
  $x = ...;
  [download]

  do

  ...
  my $x = ...;
  [download]

• Speaking of declaring variables, don't use global variables for file handles. That hasn't been necessary for 10 years.

  open(my $fh, '>', '/tmp/data.txt')
      or die("Can't create file /tmp/data.txt: $!\n");
  print $fh $res->content;
  close($fh);
  [download]

• my $req = HTTP::Request->new(GET =>'http://SOMEURLHERE');
  my $res = $ua->request($req);
  [download]

  can be written as

  my $res = $ua->get('http://SOMEURLHERE');
  [download]

Your open statement

open(MYFILE, '/tmp/data.txt');
[download]

is opening the file for reading only. (See open.) Try this:

open(MYFILE, '>', '/tmp/data.txt') || die("Cannot open /tmp/data.txt: 
+$!");
[download]