Another suggestion. Use PerlIO::Util's tee layer:

#!/usr/bin/perl
use strict;
use warnings;

use PerlIO::Util;

*STDOUT->push_layer(tee => \my $capture_buf);

print "hello world\n";

print STDERR "captured STDOUT: '$capture_buf'";

__END__
$ ./819527.pl
hello world
captured STDOUT: 'hello world
'
[download]

My best guess is that you are writing a wrapper script to intercept prints from other code. You can accomplish this by storing the STDOUT handle locally in the script and then redirecting the STDOUT handle to a variable. This is discussed in open. Something along the lines of:

#!/usr/bin/perl
use strict;
use warnings;

open my $oldout, '>&', STDOUT or die "Can't dup STDOUT: $!";
my $stream;
close STDOUT;
open STDOUT, '>', \$stream or die "Can't open STDOUT: $!";

print "Hello!\n";
$stream .= "This line is new!\n";
print $oldout $stream;
[download]

where the above is assembled from code in open. Note that this should only be done at the highest level or undone in the same subroutine, as STDOUT is global and hence this could cause some weird action at a distance issues if you are incautious.

I'm not sure I understand from your question quite what you are trying to achieve but I wonder if IO::Tee might serve your needs.

You could override print with your own subroutine that would cache (i.e simply push into an array) everything that is printed

Overriding so that you don't have to change anything else in your script is possible but might be difficult to get right (see http://search.cpan.org/~dapm/perl-5.10.1/pod/perlsub.pod#Overriding_Built-in_Functions____ )

Easier is to change all STDOUT print statements to a simple call to your subroutine that does the caching and then prints