It's extremely straightforward.

• Initialise the count to zero.
• While haven't reached the end of the file,
  • Read a line.
  • If the line consists of a bunch of stars,
    • Add 1 to the count.
    • Format the count.
    • Append formatted count to the line.
  • Print the line.

What have you tried?

use strict;
use warnings;

my $cnt = 1;
while (<>) {
    s/$/sprintf '%04d', $cnt++/e if /^\*+$/;
    print;
}
[download]

Update: The above code functionally satisfies the OP specification. Thanks to ikegami for demonstrating several optimization techniques below.

Needless sprintf, needless match, and you should probably separate the number from the stars with a space. I'd also require at least 3 stars to trigger a match.

my $cnt = '0000';
while (<>) {
    s/^(\*{3,})$/"$1 ". ++$cnt/e;
    print;
}
[download]

Optimised: (requires 5.10+)

my $cnt = '0000';
while (<>) {
    s/^\*{3,}\K$/" ". ++$cnt/e;
    print;
}
[download]

As a one-liner: (Second version requires 5.10+)

perl -pe'BEGIN { $cnt = '0000' }  s/^(\*{3,})$/"$1 ". ++$cnt/e'
perl -pe'BEGIN { $cnt = '0000' }  s/^\*{3,}\K$/" ". ++$cnt/e'
[download]

Without an eval:

perl -ple 'BEGIN {$cnt = '0000'} $_ .= " " . ++$cnt if /\*{3,}$/'
[download]

This works for me in my linux shell:

$ cat prog.pl
use strict;
use warnings;

my $cnt = 1;
while (<>) {
    s/$/sprintf '%04d', $cnt++/e if /^\*+$/;
    print;
}
$
$
$ cat file.txt
foo boo
***
goo hoo
***********************************

bloo
$
$
$ perl prog.pl file.txt
foo boo
***0001
goo hoo
***********************************0002

bloo
$
[download]

The perl community has a strong unix tradition. The programs above are written as filters and can be called on the command line as:

perl mycode.pl < inputfile > outputfile
[download]

or

cat inputfile | perl mycode.pl > outputfile
[download]

etc....

Oh, and I forgot to mention, by the magic of the "<>" operator, the input file can just be mentioned as an argument to the program:

perl mycode.pl inputfile > outputfile
[download]