Hi!

Line 34 is

       $b[$i] = $a[$i] + $a[$j];
[download]

So obviously either $a[$i] or $a[$j] are undefined.

Now lets have a look at $i and $j:

       for($i=1;$i<=$k;$i++){              # $k = $#a + 1;
                $j = $i - 1;
[download]

The element $a["last element + 1"] is undefined, and that's the reason for your error.

The solution is simple: just let your loop process one element less:

       for($i=1;$i<$k;$i++)
[download]

You're doing the right thing by checking errors - you've made a classic error which is easy to fix. You are off by one in:

for($i=1;$i<=$k;$i++)
[download]

which should be:

for($i=1;$i<$k;$i++){
[download]

You're not quite done though. As you can see from your current output, you're missing the top of Pascal's triangle:

1
11
[download]

Tongue-in-cheek comment: you could try handing this in for your homework and see if you get away with it:

$ perl -wE 'for (0 .. 4) { say 11**$_ }'
1
11
121
1331
14641
[download]

Since addition treats undef as 0, and that is what you, just switch off the warning:

        for($i=1;$i<=$k;$i++){
            $j = $i - 1;
            no warnings 'uninitialized';
            $b[$i] = $a[$i] + $a[$j];
        }
[download]

Are you sure the values in your for loop in the sub are what you expect?

...
for($i=1;$i<=$k;$i++){
    print "i = $i, j= $j\n"; # Added to debug
...
[download]

I think you'll find the following does the trick:

for($i=1;$i<$k;$i++){
[download]

(Less than versus less than/equal to)

or if you happen to be writing Perl rather than C you could:

for my $i (1 .. $k - 1) {
[download]

True laziness is hard work

Usually a warning tells you that there is a good chance that you have a bug or at least a problem that might bite you later in your program.

As is the case here: Your loop control should be $i<$k, not $i<=$k, because $a[$k] is not defined. This bug luckily doesn't change the result and only leads to a warning

#!/usr/bin/perl --

use strict;
use warnings;

Main();
exit(0);

sub Main {
    my @a;
    for ( 0 .. 10 ) {
        print Dumpyh( @a = yh(@a) );
    }
} ## end sub Main

sub yh {
    my (@a) = @_;
    my @b = (1);

#~     for ( my $i = 1 ; $i < @a ; $i++ ) {
    for my $i ( 1 .. $#a ) {
        $b[$i] = $a[$i] + $a[ $i - 1 ];
    }
    $b[@a] = 1;
    return @b;
} ## end sub yh

sub Dumpyh {

#~     return @_, "\n";
#~     return "@_\n";
    my $s = "@_";
    join '', ' ' x ( abs( 40 - length $s ) / 2 ), "$s\n";
} ## end sub Dumpyh

__END__

                   1
                  1 1
                 1 2 1
                1 3 3 1
               1 4 6 4 1
             1 5 10 10 5 1
            1 6 15 20 15 6 1
          1 7 21 35 35 21 7 1
         1 8 28 56 70 56 28 8 1
      1 9 36 84 126 126 84 36 9 1
  1 10 45 120 210 252 210 120 45 10 1
[download]

Tutorials: Arrays: A Tutorial/Reference, Variables and Scoping, Context tutorial

Converting to a HOP-style iterator left as an exercise.

(defn lazy-triangle 
  ([]
    (cons [1] (lazy-triangle [1])))
  ([row]
    (let [pairs (partition 2 1 row)
          next-row (concat [1] (map #(apply + %) pairs) [1])]
      (lazy-seq (cons (vec next-row) (lazy-triangle next-row))))))
;;
;; user=> (pprint (take 10 (lazy-triangle)))
;; ([1]
;;  [1 1]
;;  [1 2 1]
;;  [1 3 3 1]
;;  [1 4 6 4 1]
;;  [1 5 10 10 5 1]
;;  [1 6 15 20 15 6 1]
;;  [1 7 21 35 35 21 7 1]
;;  [1 8 28 56 70 56 28 8 1]
;;  [1 9 36 84 126 126 84 36 9 1])
;;
[download]

Pascal's triangle...

hth,
PooLpi

That is better written using Perl than C. Consider:

#!/usr/bin/perl
use strict;
use warnings;

my @row;

print "1\n";
for (0 .. 10) {
    @row = yh(@row);
    print "@row\n";
}


sub yh {
    my @prevRow = @_;
    my @nextRow = 1;

    if (@prevRow) {
        for my $i (1 .. $#prevRow) {
            $nextRow[$i] = $prevRow[$i - 1] + $prevRow[$i];
        }
    }
 
    push @nextRow, 1;
    return @nextRow;
}
[download]

Prints:

1
1 1
1 2 1
1 3 3 1
1 4 6 4 1
1 5 10 10 5 1
1 6 15 20 15 6 1
1 7 21 35 35 21 7 1
1 8 28 56 70 56 28 8 1
1 9 36 84 126 126 84 36 9 1
1 10 45 120 210 252 210 120 45 10 1
1 11 55 165 330 462 462 330 165 55 11 1
[download]