Here is some code that should do what you looking for:

print pack 'c*', map {hex $_} qw(48 65 6c 6c 6f 2c 20 77 6f 72 6c 64 2
+1);
[download]

produces:

Hello, world!
[download]

The map function is what I was missing. That works perfectly. Thank you.

use strict;
use warnings;

while(<DATA>) {
   chomp;
   my @hex_chars = split;
   map { print chr(hex($_)); } @hex_chars;
   print "\n";
}

__DATA__
48 65 6c 6c 6f 2c 20 77 6f 72 6c 64 21
[download]

Try this:

use strict;
use warnings;

my $line = '48 65 6c 6c 6f 2c 20 77 6f 72 6c 64 21';
my @cbytes = split / /, $line;
my $retString;

foreach my $byte (@cbytes)
{
    my $hex = '0x'.$byte;
    my $value = eval $hex;
    my $char = chr $value;
    $retString .= $char;
}

print $retString;
[download]

The trick is that perl will evaluate a literal number as hex if you prefix it with '0x', you then need to use eval to force perl to re-evalute it as a number instead of a string. From there is is just a matter of using chr (see perlfunc) to turn that number into a 1 char string.

The trick is that perl will evaluate a literal number as hex if you prefix it with '0x', you then need to use eval to force perl to re-evalute it as a number instead of a string.

Any reason not use the build in hex function, and instead use an eval, which, if the data comes from an untrusted source, has potential to have some "unwanted"side effects?

Only that I did not think to use hex. It would probably be a better approach than eval.

I don't think the OP had reason to distrust the input data, but if he did then it would be wise to sanitise with a regular expression like:my($clean) = ($raw =~ m/(\d+)/); regardless of how it is processed further.

$ echo "48 65 6c 6c 6f 2c 20 77 6f 72 6c 64 21" | perl -lpe's/([[:xdig
+it:]]{2})\s*/ chr hex $1 /eg'
Hello, world!
[download]

echo '48 65 6c 6c 6f 2c 20 77 6f 72 6c 64 21' | perl -lane 'for $ch ( 
+split /\s/ ) { $st .= chr(hex($ch)); } print $st;'
[download]

You are using the  -a switch which splits the fields on whitespace and puts them in  @F so you could write that as:

echo '48 65 6c 6c 6f 2c 20 77 6f 72 6c 64 21' | perl -lane '$st .= chr
+ hex for @F; print $st;'
[download]

FYI, the pack/unpack functions can also sometimes be very useful.

#!/usr/bin/perl -w
use strict;

open ( SOMEFILE, '<', "$ARGV[0]" )
    or die "Can't open $ARGV[0] for reading.\n";

while (defined($_ = <SOMEFILE>))
    {
    my @cbytes = split;
    my @hbytes = map(hex, @cbytes);
    my $hstring = pack('c*', @hbytes);
    }

close SOMEFILE;
[download]

99 00 00 00 dd 02
[download]

Character in 'c' format wrapped in pack at ./test.pl line 11, <SOMEFIL
+E> line 1.
Character in 'c' format wrapped in pack at ./test.pl line 11, <SOMEFIL
+E> line 1.
[download]

Use the pack template 'C*' instead of 'c*'. The latter only handles byte values up to 127, the former handles up to 255.

By the way, you could speed up your processing of that data enormously by skipping the split multiple maps over hex and chr et al. by using:

$s = '48 65 6c 6c 6f 2c 20 77 6f 72 6c 64 21';;
$s =~ tr[ ][]d; 
print pack 'H*', $s;;
Hello, world!
[download]

Thanks. I don't know how I missed that.

while (<SOMEFILE>) {
@bytes = split //;
print join ":", @bytes;
}
[download]

Please try your suggestion with an example. It's very wrong.