Can someone suggest to me what I'm doing wrong?

The .+ looks wrong, since it can match [[ and ]] too. You should use [^\]]+ in the first place.

Update: Here's a working regex:

\[\[([^\]]+)]]
[download]

But it stops at a single ]. To prevent that, you need a negative look-ahead:

\[\[((?:(?!\]\]).)+)]]
[download]

Now that's quite unreadable, so here in detail:

\[\[            # opening delimiter
(               # capture...
  (?:           # a group
    (?!\]\])    #    that does not start with ]]
    .           #    and is a single character long
  )+            # and many of these groups, at least one.
)
]]              # closing delimiter
[download]

To prevent that, you need a negative look-ahead:

No, you don't.

$_ = "[[foo]] bar [[baz ] qux]] [quux]] fred [[waldo]]]";
say $1 while /\[\[([^]]*(?:\][^]]+)*)\]\]/g;
__END__
foo
baz ] qux
waldo
[download]

This uses some classical loop-unrolling, and is, IIRC, similar how Mastering Regular Expressions (first edition) matches C comments.

Hi,

Aaah ok - so I was calling it AFTER, which basically meant that it wasn't matching the string at the point I was expecting :) Thanks for that!

This works fine now:

$test =~ s{\[\[([^\]]+)\]}{
print "FOO: $1 \n";    
}ge;
[download]

Thanks again!

Andy

Hi,

Thanks - just having a look into those negative look-ahead stuff, as I'm sure that will be good to know for other regexes.

You example doesn't seem to work?

\[\[            # opening delimiter
(               # capture...
  (?:           # a group
    (?!\]\])    #    that does not start with ]]
    .           #    and is a single character long
  )+            # and many of these groups, at least one.
)
]]              # closing delimiter
[download]

"Substitution replacment not terminated at line24"

any ideas?

TIA

Andy

moritz's example is meant to be used with the x modifier which permits comments in a regex. For example:

my $re= qr{\[\[            # opening delimiter
(               # capture...
  (?:           # a group
    (?!\]\])    #    that does not start with ]]
    .           #    and is a single character long
  )+            # and many of these groups, at least one.
)
]]              # closing delimiter
}x;

while ($test =~ m{$re}g) {
  print "FOO:<$1>\n";
}
[download]

A few additional points:

• I notice that you want \| in your output. If you use qq|...| to quote the string you'll need to escape "\|" with "\\\|", not "\|". "\\" to escape the "\" and "\|" to escape the pipe.

  Alternatively, you could simplify matters and use a single quote syntax such as q{...} or any other delimiter that isn't in your string. \ will be taken literally, and the curly brace delimiters don't show up in your string so there is no need to escape the pipe or any other character.

• If you know that bad tags end in double square braces you can dispense with the negative lookahead  m{\[\[([^\[]+)\]\]}g The main thing to get rid of is that (.+) because "." matches everything including the end of tag character.

• When testing output via print statements, it is a good idea to put the delimiters front and back, just in case there is invisible whitespace at the beginning or end of your match, i.e. print "FOO:<$1>\n".

Revised code incorporating above points:

my $test = q{asdfas dfas dfas df asfd[[bad tag]] [[table]] asdfa sf as
+ [[asdf as f\|sfds]] as dfa 
sdf [[test new line]] foo};

while ($test =~ m{\[\[([^\[]+)\]\]}g) {
  print "FOO:<$1>\n";
}

#output - same as required in OP
FOO:<bad tag>
FOO:<table>
FOO:<asdf as f\|sfds>
FOO:<test new line>
[download]

Hi,

Thanks - the \| is only there cos I am using qq|| (so using | in the string, causes perl to break :))

The actual code people will use, is:

[[foo|bar]] , not [[foo\|bar]]

Cheers

Andy

                  |
                  v
$test =~ s{\[\[(.+?)[^\]\]]}{
   print "FOO: $1\n";    
}ge;
[download]

I'm really not sure why you are replacing the tags with the result of print, though. Unless the print is just a placeholder until you get this working, the code should be

while ($test =~ s{\[\[(.+?)[^\]\]]}g) {
   print "FOO: $1\n";    
}
[download]

The pattern is wrong, and you don't want s///.

while ($test =~ m{\[\[(.+?)\]\]}g) {
   print "FOO: $1\n";    
}
[download]

ack, that's what I thought I was posting. Thanks.