in reply to Regex question - negatives

Can someone suggest to me what I'm doing wrong?

The .+ looks wrong, since it can match [[ and ]] too. You should use [^\]]+ in the first place.

Update: Here's a working regex: 

\[\[([^\]]+)]]

[download]

But it stops at a single ]. To prevent that, you need a negative look-ahead: 

\[\[((?:(?!\]\]).)+)]]

[download]

Now that's quite unreadable, so here in detail: 

\[\[            # opening delimiter
(               # capture...
  (?:           # a group
    (?!\]\])    #    that does not start with ]]
    .           #    and is a single character long
  )+            # and many of these groups, at least one.
)
]]              # closing delimiter

[download]
Perl 6 - second systems done right

Replies are listed 'Best First'.
Re^2: Regex question - negatives
by JavaFan (Canon) on Jan 13, 2011 at 10:52 UTC
    To prevent that, you need a negative look-ahead:
    No, you don't. 
    $_ = "[[foo]] bar [[baz ] qux]] [quux]] fred [[waldo]]]";
say $1 while /\[\[([^]]*(?:\][^]]+)*)\]\]/g;
__END__
foo
baz ] qux
waldo

    [download]
    This uses some classical loop-unrolling, and is, IIRC, similar how Mastering Regular Expressions (first edition) matches C comments.
[reply]
[d/l]
Re^2: Regex question - negatives
by ultranerds (Hermit) on Jan 13, 2011 at 09:49 UTC
    Hi,

    Aaah ok - so I was calling it AFTER, which basically meant that it wasn't matching the string at the point I was expecting :) Thanks for that!

    This works fine now: 
    $test =~ s{\[\[([^\]]+)\]}{
print "FOO: $1 \n";    
}ge;

    [download]
    Thanks again!

    Andy
[reply]
[d/l]
Re^2: Regex question - negatives
by ultranerds (Hermit) on Jan 13, 2011 at 10:24 UTC
    Hi,

    Thanks - just having a look into those negative look-ahead stuff, as I'm sure that will be good to know for other regexes.

    You example doesn't seem to work? 
    \[\[            # opening delimiter
(               # capture...
  (?:           # a group
    (?!\]\])    #    that does not start with ]]
    .           #    and is a single character long
  )+            # and many of these groups, at least one.
)
]]              # closing delimiter

    [download]
    "Substitution replacment not terminated at line24"

    any ideas?

    TIA

    Andy
[reply]
[d/l]

      moritz's example is meant to be used with the x modifier which permits comments in a regex. For example:

      my $re= qr{\[\[            # opening delimiter
(               # capture...
  (?:           # a group
    (?!\]\])    #    that does not start with ]]
    .           #    and is a single character long
  )+            # and many of these groups, at least one.
)
]]              # closing delimiter
}x;

while ($test =~ m{$re}g) {
  print "FOO:<$1>\n";
}

      [download]
[reply]
[d/l]
[select]
        Hi,

        Ah cool, didn't know about that feature either =)

        Seems it doesn't wanna work with a s/// though?

        This works fine, and prints out all the tag I expected: 
        while ($test =~ m{$re}g) {
   print "FOO:<$1>\n";
}

        [download]
        ..while this only prints out the "test new line" one for some reason? 
        $test =~ s{$re}{
    print "BLA: $1 \n";
}ge

        [download]
        EDIT, never mind - me being stupid with my syntax ;)

        TIA

        Andy
[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom