I'm not sure that extracting things is the right approach. Instead I'd try to replace all newlines with \n$prefix (resp. all "starts" of the string with the prefix, in REspeak):

sub prefix_print {
    # unfortunately, the local copy of $_ is necessary to be able to p
+refix_print
    # constants
    print map { my $l = $_; $l =~ s/^/$prefix/gm; $l } @_
};

prefix_print qq(foo\nbar),2,3,4
[download]

What do you want from the following?

prefix_print("A\nB");
prefix_print("C\n");
[download]

Update: I might do something like the following:

Good catch. I imagine a "\n" would need to be added.

Another one:

sub prefix_print {
    print map $_ ne "\n" ? "$prefix$_":$_, split /(\n)/, join '',@_;
}
[download]

The split /(\n)/ also returns the newlines, so you can prefix anything that isn't a newline, while passing the newlines through as is.  This way, you don't have to take care of boundary cases like trailing newline and initial prefix.

Some clear solutions:

my $s = join('', @_); $s =~ s/^/$prefix/mg; print $s;
[download]

print map { $prefix . $_ } split /^/m, join('', @_);
[download]

print apply { s/^/$prefix/mg } join('', @_);
[download]

print join('', @_) =~ s/^/$prefix/rmg;
[download]

apply comes from List::MoreUtils

The last requires Perl 5.14 for /r.

Being an old crotchety person by now, I take the Clark Gable Approach™ to such things:   “Frankly, my dear, I don’t give a damn”™ about how you write it, as long as what you write is abundantly clear.   The original version of this code was, indeed, clear.   (Therefore:   priceless.)   Save the rest for “Obfuscation” and “Poetry.”

Q:   Can we do without an auxiliary variable here?
A:   Clark Gable.™

Right. The only reason to change clear code I see is a massive performance problem in the respective code, typically shown by running a profiler. Everything else is premature optimization and thus evil^TM.

Alexander

--
Today I will gladly share my knowledge and experience, for there are no sweeter words than "I told you so". ;-)

This is an interesting aspect, because in the end, I found ikegami's solution using map in combination with /^/ easier to understand than my original one, once I understood it. Before this, I was not aware that matching on /^/ could make sense (Perl's universe of regular expression exceeds my current knowledge by far). Probably that's typical for readability questions: Readability depends also very much on the experience of the reader...
-- 
Ronald Fischer <ynnor@mm.st>

print map { "$prefix$_" } split /\n/, join '', @_
[download]

print map { "$prefix$_" }  join('',@_) =~ m/([^\n]+\n?)/g
[download]

print map { "$prefix$_" } split /\n/, join '', @_

Fixed:

print map { "$prefix$_" } split /^/m, join('', @_), -1;
[download]

Note: split implies the "m" for that pattern, but it's clearer to specify it.

Update: As Eliya kinda points out, there won't ever be null trailing fields with that pattern, so the above can be simplified to

print map { "$prefix$_" } split /^/m, join '', @_;
[download]

Great solution! I completely forgot about the "negativ LIMIT" parameter of split.
-- 
Ronald Fischer <ynnor@mm.st>

Compact solution, but unfortunately doesn't fulfil the specification:

The first solution is not correct, because it would drop the newline characters. The second solution keeps most newline characters, but if the string contains a sequence of \n, all but the first are ignored...

-- 
Ronald Fischer <ynnor@mm.st>

rovf:

I rather like:

#!/usr/bin/perl
use warnings;
use strict;

my $prefix="prefix: ";
sub printpre {
        unshift @_, $prefix;
        print @_;
}

printpre "apple ", "banana ", "tomfoolery ", "\n";
[download]

...roboticus

When your only tool is a hammer, all problems look like your thumb.

Why not write that without the auxiliary array manipulation there?

chromatic:

Ha, ha! It never occurred to me!

#!/usr/bin/perl
use strict;
use warnings;
my $prefix="Prefix: ";
sub print_prefix {
    print $prefix, @_;
}
print_prefix "alpha ", "beta ", "gamma\n";
[download]

Sigh. When I read your reply, I thought, "Hmm, does unshift return a reference to the array?", so a first I thought you were prompting me to do something like:

print unshift @_, $prefix;
[download]

But when I checked the docs, I could see that it wouldn't fly. Then I understood what you meant. Ah, well! I'm always amused at how my mind works: it seems I frequently complicate simple things. ;^)

...roboticus

When your only tool is a hammer, all problems look like your thumb.

It seems to me the OP has a logger and he wants to include the prefix at the start of every line, not the start of every message. Those aren't the same if there's a possibility of multi-line messages.

This would not cope when there are "\n" in between. See the comment by ikegami.

-- 
Ronald Fischer <ynnor@mm.st>

rovf:

Yeah, I clearly missed on that one. I then tried:

sub print_prefix {
    local $/="\nPrefix: ";
    print @_;
}
[download]

But that didn't work. On first guess, I thought it would do OK. After reading the documentation, I thought it would print it at least once. But what I got was...nothing. It never printed prefix at all. The only other methods I could think of had already been covered.

...roboticus

When your only tool is a hammer, all problems look like your thumb.

Could someone explain where these matches come from?

Calling your second version with prefix_print('y'), I get "PyP", not "PyPP". I am testing with perl 5.12.2, default compile from source on linux.

The match returns two matches on my system:

1. the 'y' at the end of the line
2. then '' (.* can match nothing) at the end of the line

It would be an infinite loop (forever matching nothing at the end of the line) except for Repeated Patterns Matching a Zero length Substring

I can't imagine how you got "PyPP"