What 'this'? Here's a way to run through the XML and replace the contents of mml:mi elements with '...'. Maybe that's enough to get you started?

#!/usr/local/bin/perl
use strict;
use warnings;
use XML::Twig;

my $xml = <<XML;
<mml:math xmlns:mml="http://www.w3.org/1998/Math/MathML">
  <mml:mstyle mathsize="1em">
    <mml:mi>s</mml:mi>
    <mml:mo>+</mml:mo>
    <mml:mi>s</mml:mi>
  </mml:mstyle>
</mml:math>
XML

my $twig = XML::Twig->new (
    twig_roots => {'mml:mi' => \&subst,},    # process the element
    twig_print_outside_roots => 1,           # print the rest
);
$twig->parse ($xml);


sub subst {
    my ($twig, $value) = @_;

    print '<mml:mi>...</mml:mi>';
}
[download]

Prints:

<mml:math xmlns:mml="http://www.w3.org/1998/Math/MathML">
  <mml:mstyle mathsize="1em">
    <mml:mi>...</mml:mi>
    <mml:mo>+</mml:mo>
    <mml:mi>...</mml:mi>
  </mml:mstyle>
</mml:math>
[download]

Update: fix copy and paste madness.

Thank you so much!!
That is very helpful for me.
BTW
Can I add some conditions in <subst>?
The original xhtml file:

....
 <mml:mi>s</mml:mi>
 <mml:mi>sin</mml:mi>
..
[download]


Only <mml:mi>s</mml:mi> just replace with <mml:mi>x</mml:mi>.
the result:
New xhtml file

....
 <mml:mi>x</mml:mi>
 <mml:mi>sin</mml:mi>
..
[download]

Sure. Change the sub to:

sub subst {
    my ($twig, $value) = @_;

    $value->subs_text ('^s$', 'x');
    $value->print ();
}
[download]

I can thoroughly recommend the XML::Twig documentation by the way. It is long, but there are some really good examples.

True laziness is hard work

This will replace <mml:mi>s</mml:mi> with <mml:mi>S</mml:mi>

#!/opt/perl/bin/perl

use Modern::Perl;
use XML::Twig;

my $xml = do { local $/; <DATA> };

my $twig=XML::Twig->new(TwigHandlers => {'mml:mi' => \&mmlmi});
$twig->parse($xml);
$twig->print(pretty_print => 'indented');

sub mmlmi {
    my ($fromtwig, $mmlmifrom) = @_;
    my $mmlmi = $mmlmifrom->text;
    if ($mmlmi eq 's') {
        $mmlmifrom->set_text('S');
    }
}

__DATA__
<mml:math xmlns:mml="http://www.w3.org/1998/Math/MathML">
  <mml:mstyle mathsize="1em" displaystyle="true" mathcolor="#0000ff" f
+ontfamily="serif">
    <mml:mrow>
      <mml:msubsup>
        <mml:mstyle displaystyle="true">
          <mml:mo>&#x222b;</mml:mo>
        </mml:mstyle>
        <mml:mn>0</mml:mn>
        <mml:mn>4</mml:mn>
      </mml:msubsup>
    </mml:mrow>
    <mml:msqrt>
      <mml:mrow>
        <mml:mrow>
          <mml:msup>
            <mml:mi>s</mml:mi>
            <mml:mn>2</mml:mn>
          </mml:msup>
        </mml:mrow>
        <mml:mo>+</mml:mo>
        <mml:mi>s</mml:mi>
      </mml:mrow>
      <mml:mspace width="0em" height="1.2ex" />
    </mml:msqrt>
    <mml:mo maxsize="1">(</mml:mo>
    <mml:mn>2</mml:mn>
    <mml:mi>s</mml:mi>
    <mml:mo>+</mml:mo>
    <mml:mn>1</mml:mn>
    <mml:mo maxsize="1">)</mml:mo>
    <mml:mspace width="0.167em" />
    <mml:mi>d</mml:mi>
    <mml:mi>s</mml:mi>
  </mml:mstyle>
</mml:math>
[download]

You could use parsefile instead of parse to read from the file system, and print_to_file instead of the print to write it back to the file system

20110510 @ 11:32 UTC Added print_to_file & parsefile

20110510 @ 12:52 UTC Added ! to first line. Doh!

Thank you for GrandFather, cjb and choroba!

These responses are very valuable and helpful for me.

open 903926.xml ;
map :i {s/(.*)/[$1]/} //mml:mi[text()!="s"] ; # wrap non-s in square b
+rackets
map "..."  //mml:mi[text()="s"] ;             # replace s with ...
[download]