Re: Joining an array

This does the trick...

use Modern::Perl;
my @t   = qw(name John number 7 status unknown);
my $str = '';
while (@t) {
    $str .= sprintf('%s=%s', shift @t, shift @t);
    $str .= '&' if @t;
}
say $str;
[download]

Though if what you're trying to do is construct a query string for a URI, you want to use URI::Escape, which will escape any special characters in your string. (For example, what if one of the strings in your array already contains an equals sign?)

use Modern::Perl;
use URI::Escape qw/uri_escape/;
my @t   = qw(name John number 7 status unknown);
$t[1] = 'John Smith';  # something that needs escaping
my $str = '';
while (@t) {
    $str .= sprintf(
        '%s=%s',
        uri_escape(shift @t),
        uri_escape(shift @t),
        );
    $str .= '&' if @t;
}
say $str;
[download]

It's a shame you said that the order matters. If it didn't, then casting your array to a hash would be a neat trick:

use Modern::Perl;
use URI::Escape qw/uri_escape/;
my @t   = qw(name John number 7 status unknown);
my %th  = @t;   # cast to hash
my $str = join '&',
    map { sprintf '%s=%s', uri_escape($_), uri_escape($th{$_}) }
    keys %th;
say $str;
[download]

Comment on Re: Joining an array Select or Download Code

Replies are listed 'Best First'.
Re^2: Joining an array by CountZero (Bishop) on Feb 11, 2012 at 19:00 UTC
Didn't you notice that the keys are in alfabetical order? If you just `sort` the keys your casting trick will work. CountZero A program should be light and agile, its subroutines connected like a string of pearls. The spirit and intent of the program should be retained throughout. There should be neither too little or too much, neither needless loops nor useless variables, neither lack of structure nor overwhelming rigidity." - The Tao of Programming, 4.1 - Geoffrey James	[reply] [d/l]
Re^2: Joining an array by tangent (Parson) on Feb 11, 2012 at 00:57 UTC
I take care of the escaping at an earlier stage (I should have put `&` in there as that is what I actually use but didn't format it properly in the post). The sprintf syntax has always confused me but I can see clearly here how it works. Very nice. Just wondering how concatenation compares with the other methods above performance wise as I'll be doing this up to a thousand times a go. I'll go and benchmark it.	[reply] [d/l]
Re^3: Joining an array by tobyink (Canon) on Feb 11, 2012 at 09:02 UTC
Generally speaking I prefer `sprintf` over interpolation (`"$foo=$bar"`) except in very trivial cases. When you need to put `$foo` and `$bar` into a string, interpolation is fine. But if you need to put `$foo->[1]{name}` and `encode_entities($bar->get_url("print"))` into a string, `sprintf` looks much better: `sprintf( '<a href="%s">%s (printable version)</a>', encode_entities($bar->get_url("print")), $foo->[1]{name}, );` [download] Bear in mind that if you're outputting this URL in HTML, there are two types of escaping you need; and you need to do them both at the appropriate stage. `use Modern::Perl; use URI::Escape qw/uri_escape/; use HTML::HTML5::Entities qw/encode_entities/; my @t = qw(name John number 7 status unknown); my %th = @t; # cast to hash my $url = 'show_person.cgi?' . join '&', map { sprintf '%s=%s', uri_escape($_), uri_escape($th{$_}) } keys %th; printf( '<a href="%s">%s</a>', encode_entities($url), encode_entities($th{name}), );` [download] That is, URI escaping (which deals with things like space being encoded as `%20`) needs to be done to each component of the URI, but not the URI as a whole. And HTML entity encoding (which deals with things like "&" becoming "&") needs to be done to all strings used in the HTML. That assumes you're building your HTML using string processing, which is what many people do. If you're instead building it using a DOM library (e.g. XML::LibXML, HTML::HTML5::Builder, etc) then the library should take care of the HTML entity encoding, but it won't attempt URI escaping.	[reply] [d/l] [select]
Re^4: Joining an array by tangent (Parson) on Feb 11, 2012 at 16:23 UTC
Thanks for that tobyink. In my specific case there is no need for escaping as everything I will be using as a key or value is guaranteed to only consist of `[a-zA-Z_-]` and this is enforced at the data entry stage. BTW I have been doing some benchmarking and so far sprintf rocks, though I have a feeling some of this is to do with the extra method call overhead using a module. Haven't included the newer ones below yet.	[reply] [d/l]