Generally speaking I prefer sprintf over interpolation ("$foo=$bar") except in very trivial cases.

When you need to put $foo and $bar into a string, interpolation is fine. But if you need to put $foo->[1]{name} and encode_entities($bar->get_url("print")) into a string, sprintf looks much better:

sprintf(
    '<a href="%s">%s (printable version)</a>',
    encode_entities($bar->get_url("print")),
    $foo->[1]{name},
    );
[download]

Bear in mind that if you're outputting this URL in HTML, there are two types of escaping you need; and you need to do them both at the appropriate stage.

use Modern::Perl;
use URI::Escape qw/uri_escape/;
use HTML::HTML5::Entities qw/encode_entities/;
my @t   = qw(name John number 7 status unknown);
my %th  = @t;   # cast to hash
my $url = 'show_person.cgi?' .
    join '&',
    map { sprintf '%s=%s', uri_escape($_), uri_escape($th{$_}) }
    keys %th;
printf(
    '<a href="%s">%s</a>',
    encode_entities($url),
    encode_entities($th{name}),
    );
[download]

That is, URI escaping (which deals with things like space being encoded as %20) needs to be done to each component of the URI, but not the URI as a whole. And HTML entity encoding (which deals with things like "&" becoming "&") needs to be done to all strings used in the HTML.

That assumes you're building your HTML using string processing, which is what many people do. If you're instead building it using a DOM library (e.g. XML::LibXML, HTML::HTML5::Builder, etc) then the library should take care of the HTML entity encoding, but it won't attempt URI escaping.

Thanks for that tobyink. In my specific case there is no need for escaping as everything I will be using as a key or value is guaranteed to only consist of [a-zA-Z_-] and this is enforced at the data entry stage.

BTW I have been doing some benchmarking and so far sprintf rocks, though I have a feeling some of this is to do with the extra method call overhead using a module. Haven't included the newer ones below yet.