my @fileNames = [ "manimp1.txt", "manimp2.txt" ];
[download]

to:

    my @fileNames = ( "manimp1.txt", "manimp2.txt" );
[download]

The square brackets create a reference to an array. I think you just want to construct an array. See also:

• perldsc
• perlref

Yes, that did the trick, thank you.

You appear to be passing variables --$count and $newPrices{key} -- into getFiles() as arguments to the call. By doing it that way, your sub changes their values in main and in the sub. For example, if the first file has three lines and the second has four, and if the value of $count in main is 0 on entry to the sub, its value will be 7 when you return from the sub. That's probably a non-issue in the particular case, but it's a behavior of which you want to be aware.

You've also written a sub with no explicit return which means the sub may do something you're not expecting, as explained in perlsub:

"If no "return" is found and if the last statement is an expression, its value is returned."

All in all, then, I commend a close reading of perlsub re return and also with special attention to the explanation of passing variables by reference.

Update: clarifiation, p2, sentence 2 and fixed markup.

Thanks for your input. I do know that a sub with no explicit return, it could create some unexpected return value. The subroutine is supposed to make changes to global hashes and I am not really relying on the return, so I am not too bothered by it. The  $count variable is a global in this case and I want to count all lines in the files. I made a few pretty drastic changes today, and I will continue to do that as I learn more stuff. One of the things I did was to reduce the number of global variables. I hope to eliminate global variables after I read what you suggested.

sub getFiles {
    my @fileNames = [ "manimp1.txt", "manimp2.txt" ];
    for my $i (0..$#fileNames) {
        open (FILE, "<", $fileNames[$i]) or die "Couldnt open file:  $
+fileNames[$i]\n";
        while (<FILE>) {
            $count++;
            my @line_array = split (/\t/, $_);
            chomp(@line_array);
            my $key = shift(@line_array);
            my $aref = [@line_array];
            $newPrices{$key} = $aref;
        }
        delete ($newPrices{'Part Num.'});
    }
}
[download]

That would probably be better as:

sub getFiles {
    my @fileNames = ( 'manimp1.txt', 'manimp2.txt' );
    for my $file ( @fileNames ) {
        open my $FILE, '<', $file or die "Couldnt open file:  $file be
+cause: $!";
        while ( <$FILE> ) {
            chomp;
            my ( $key, @line_array ) = split /\t/;
            $newPrices{ $key } = \@line_array;
        }
        $count += $.;
        delete $newPrices{ 'Part Num.' };
    }
}
[download]

Thanks for the input. The line:

$newPrices{ $key } = \@line_array;
[download]

is what I had originally, but my understanding is that is a reference to the array, and since the array changes when the next line is read, it made all the values in my hash the same, the last line of the last file. I understand that using  $newPrices{ $key } = [@line_array] creates a copy of the array. It is quite possible that I am mistaken since this is the first time I have really sat down with Perl.

my ( $key, @line_array ) on the previous line creates a new variable each time through the loop so it is safe to use a reference to this variable.    If the variable was in a larger scope then what you describe would be a problem.

my @fileNames = ( "manimp1.txt", "manimp2.txt" );
foreach my $file (@fileNames)
{
   processFile($file);
}

sub processFile
{
   my $fileName = shift;
   open (....)
   ... what is supposed to happen here?
}
[download]

Well, yes the two files are related. They both contain parts of a single price file from one of our suppliers. My goal is to open each file and read it into a hash. What I am attempting to do is place each line in an array and perform some operations on the line before it goes into the hash. I have worked on it a little today but it is on my work VM and it is late so I don't feel like firing up my laptop to VPN. I will place the new script on my scratchpad tomorrow.