This subroutine accepts a list of numbers, and returns a list of hashrefs that look like: { $number => [ $idx1, $idx2, $idx_n, ... ] }, where each index represents where that particular number will be found in the original list.

use strict;
use warnings;
use Data::Dump 'dump';

my @numbers = ( 1, 2, 2, 4, 8, 42, 7, 2, 6, 7, 9, 42 );

my @duplicate_locations = find_duplicates( @numbers );

dump @duplicate_locations;


sub find_duplicates {
    my @list = @_;
    my $idx;
    my %buckets;
    foreach my $item ( @list ) {
        push @{$buckets{$item}}, $idx++;
    }
    my @rv;
    foreach my $key ( keys %buckets ) {
        push @rv, { $list[$buckets{$key}->[0]] => $buckets{$key} }
            if @{$buckets{$key}} > 1;
    }
    return @rv;
}
[download]

The output...

({ 42 => [5, 11] }, { 7 => [6, 9] }, { 2 => [1, 2, 7] })
[download]

Update:Simplifying the data structure returned simplifies the subroutine that produces it:

use strict;
use warnings;
use Data::Dump 'dump';

my @numbers = ( 1, 2, 2, 4, 8, 42, 7, 2, 6, 7, 9, 42 );

dump { find_duplicates( @numbers ) };


sub find_duplicates {
    my @list = @_;
    my $idx;
    my %buckets;
    foreach my $item ( @list ) {
        push @{$buckets{$item}}, $idx++;
    }
    delete @buckets{ grep { @{$buckets{$_}} < 2 } keys %buckets };
    return %buckets;
}
[download]

Now the output is...

{ 2 => [1, 2, 7], 7 => [6, 9], 42 => [5, 11] }
[download]

...so the actual return value from the sub is a hash where the keys are the values from your original list, and the values are array refs containing lists of where the corresponding elements are found. ...and we've stripped away any that weren't duplicated.

Thanks a lot you guys thats great coding, I will definately not need more than this, what i had so far was this, but your scripts definately beat it, although i made it if this is unequal put it in this list just to get more understanding of what i had to do.

foreach @allcards {
if $allcards[$count] != @userinput[0] or 
if $allcards[$count] != @userinput[1] or 
if $allcards[$count] != @userinput[2] or 
if $allcards[$count] != @userinput[3] or
if $allcards[$count] != @userinput[4] or
if $allcards[$count] != @userinput[5] {
push (@resthand,$allcards[$count]);
}
count++;}
[download]

Where's your code that you have tried?

I'll be nice share some code that should get you started. I'll leave it to you to figure out how to bundle it in a subroutine, how to pass data into and out of it, and any other modifications you need to meet your needs.

use strict;
use warnings;

my (@list) = (1,1,2,3,4,4,4,5,6,7,7,8,9,10);

my %check;

foreach my $item (@list) {
    if (exists $check{$item}) {$check{$item}++;}
    else {$check{$item} = 1;}
}

foreach my $key (keys %check) {
    my $count = $check{$key};
    if ($count > 1) {
        print "$key was in the list $count times.\n";
    }
}
[download]

There is no need to check if the $item exists in the hash. When you increment a the value for a key which doesn't exist, the key springs into existence. So lines 8-11 can be replaced by:

$check{$_}++ for @list;
[download]

When you increment a the value for a key which doesn't exist, the key springs into existence.

Didn't know that. Thanks for the info.

However, I'd like to point out one thing. Back when I was first learning Perl, your one line for loop code would have had me thoroughly confused. Based on the original question asked by the OP, I was left with the impression that the OP was a bit of a beginner. In that case, my foreach loop would probably be somewhat easier to follow along and understand.

Plus, I personally find that my foreach loop more closely matches how I would think through the task, which in turn would mean easier code for me to personally maintain. Just a personal preference.

Anyways, thanks for the tip!