The trick with the alternation is that your regex matches -s delimited by B's, thus slurping them up. The next regex search starts off after the last B, and needs to skip the following -s to find the next B.

use 5.010;
use strict;
use warnings;

$_ = '------BBBBB-----------------------------------------------------
+-------------------------------------------------------BBBBBB----BBBB
+BBBB-----------------BBBBBB------------------------------------------
+--------------BBBBBBB---------------BBBBB-----BBBBBBBBB--------------
+----------------------BBBBBBBBB------BBBBBBBBB-----------------------
+-----BBBBBBBBB--------------------------------------BBBBBBBB-------BB
+BBBB---------------------BBBBBBB--------------------------BBBBBBBB---
+-';

my $expected = 'iiiiiiMMMMMooooooooooooooooooooooooooooooooooooooooooo
+oooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooMMMM
+MMiiiiMMMMMMMMoooooooooooooooooMMMMMMiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiii
+iiiiiiiiiiiiiiiiiiiiiiiiMMMMMMMoooooooooooooooMMMMMiiiiiMMMMMMMMMoooo
+ooooooooooooooooooooooooooooooooMMMMMMMMMiiiiiiMMMMMMMMMooooooooooooo
+oooooooooooooooMMMMMMMMMiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiMMMMMMM
+MoooooooMMMMMMiiiiiiiiiiiiiiiiiiiiiMMMMMMMooooooooooooooooooooooooooM
+MMMMMMMiiii';

s/(^|B+)(-+)($|B+)/ $1 . ("i" x length($2)) . $3/eg;
s/-/o/g;
s/B/M/g;

say $expected;
say $_;

say $expected eq $_ ? 'yes' : 'no';
[download]

It can be done in one s/// operation...

use v5.10;
use strict;
use warnings;

$_ = '--BBB----BB--B-------B--B--BBBB---B--';

s ((B+|.)) {
    state $char = 'i';
    if (index($1, 'B') == 0) {
        $char = $char eq 'i' ? 'o' : 'i';
        'M' x length($1);
    }
    else {
        $char;
    }
}eg;

say;
[download]

use Moops; class Cow :rw { has name => (default => 'Ermintrude') }; say Cow->new->name

That is way too complex :)

my $p = "--BBB----BB--B-------B--B--BBBB---B--";

my @x = qw( i o );
my $x = 0;

$p =~ y/B/M/;
$p =~ s/(-+)/$x[$x++%2]x length($1)/ge;

say $p;
[download]


Enjoy, Have FUN! H.Merijn

Thank you very much for your kind tips!
Will look at them carefully!

Here's another way to do it:

#!/usr/bin/env perl -l

use strict;
use warnings;

my $string = '---BB--BBB---BBB---B-B---';
print $string;

$string =~ y/B/M/;
print $string;

my @subs = qw{i o};
my $i = 1;
$string =~ s/(-+)/$subs[$i ^= 1] x length $1/eg;
print $string;
[download]

Output:

---BB--BBB---BBB---B-B---
---MM--MMM---MMM---M-M---
iiiMMooMMMiiiMMMoooMiMooo
[download]

Is this in any way related to How to format such a string? ?

Rather than focusing on how to do this in as few characters as possible, consider doing it in a manner that is clear

my $str = '---BBB--- ..... ';
my @bits = split /(B+)/, $str;
[download]

produces @bits:

0: '---'
1: 'BBB'
2:'---'
[download]

processing through @bits, you have to consider the possibility that the first character was a 'B', in which case $bits[0] will be B', in which case you convert to M's, otherwise the first part will convert to the odd pattern. Then a string of Bs, then the even pattern, and so on.

Golf:

$_ = '--BBB----BB--B-------B--B--BBBB---B--';

s/-+/--$|x$&=~y---c/ge;y/B10/Mio/;

say;
[download]

Out:

iiMMMooooMMiiMoooooooMiiMooMMMMiiiMoo
[download]

g and c
Global matching, and keep the Current position after failed matching. Unlike i, m, s and x, these two flags affect the way the regex is used rather than the regex itself. See "Using regular expressions in Perl" in perlretut for further explanation of the g and c modifiers.

Two more ways to flip between 'i' and 'o':

$char = 'i';

$char = chr 216 - ord $char;
$char =~ tr/io/oi/;
[download]