use Data::Dumper;

my @aoh = ({doc1=>2345}, {doc2=>1234}, {doc3=>5678}, {doc4=>4567});
my @sorted_aoh = sort { (%$a)[1] <=> (%$b)[1] } @aoh;

print Dumper \@sorted_aoh;

__output__

$VAR1 = [
          {
            'doc2' => 1234
          },
          {
            'doc1' => 2345
          },
          {
            'doc4' => 4567
          },
          {
            'doc3' => 5678
          }
        ];
[download]

_________
broquaint

I'll just expand on this so that it sorts on the key that starts with "doc" and ends with a number. This removes the "there must be only one key" requirement.

my @sorted_aoh = sort {
    (map /^doc(\d+)/ ? 0+$1 : (), keys(%$a))[0]
    <=>
    (map /^doc(\d+)/ ? 0+$1 : (), keys(%$b))[0]
} @aoh;
[download]

That happens to be suboptimal because every comparison is doing a potentially expensive operation to each hash. An improvement would be to use a Guttman-Rossler transform and then you get something really slick.

my @sorted_aoh =
map $aoh[ substr $_, 5 ],
sort
map {
    # Retrieve the document number
    my $doc_key = (map /^doc(\d+)$/ ? 0 + $1 : (), keys %{$aoh[$_]})[0
+];

    # Return the document number, a null and the original array index
    pack( 'N', $doc_key ) . "\0" . $_;
} 0 .. $#aoh
[download]

use strict;
use warnings; 
my %hash = ( doc1 => 2345,
      doc2 => 1234,
      doc3 => 5678,
      doc4 => 4567,
      );
my @sorted_docs = sort { $hash{$a} <=> $hash{$b} } keys %hash;
print join " " => @sorted_docs;
[download]

• See the correct representation of your hash.
• Look around. There are some valuable resources. Read QandASection: sorting and How do I sort a hash by its values?.

artist

Yet another way to do it...

my @array = ({doc1=>2345}, {doc2=>1234}, {doc3=>5678}, {doc4=>4567});
my %hash = map { %{$_} } @array;
my @sorted = sort { $hash{$a} <=> $hash{$b} } keys %hash;
print "@sorted\n";
[download]

Update: Removed each from my %hash = map { each %{$_} } @array;.

Is there a good reason why you want an array of hashes each containing a single value? I would have thought that either a single hash or an array of two element arrays might be more appropriate.

For example:

my %hash = (doc1 => 2345, doc2 => 1234, 
            doc3 => 5678, doc4 => 4567);
[download]

You could then get a list of the keys that you wanted in the right order with

my @keys = sort {$hash{$a} <=> $hash{$b} }(keys %hash);
[download]

or an array of two element arrays:

 my @array = (["doc1", 2345], ["doc2", 1234], 
              ["doc3", 5678], ["doc4", 4567]);
[download]

In this case you would sort the array with:

my @sorted = sort {$a->[1] <=> $b->[1]} @array;

Campbell