I'm not sure what you want. It's one of the following two.

1) Maybe you're looking for qr/.../.

$re = "\.";

foreach (qw( . a )) {
   print("$_ ", /$re/ ? "matches" : "doesn't match", " $re\n");
}

$re = qr/\./;

foreach (qw( . a )) {
   print("$_ ", /$re/ ? "matches" : "doesn't match", " $re\n");
}
[download]

. matches .
a matches .
. matches (?-xism:\.)
a doesn't match (?-xism:\.)
[download]

2) Maybe you're looking for \Q..\E (or quotemeta).

$var = '...';
$re = qr/abc\Q$var\Eghi/;

foreach (qw(
   abcdefghi
   abc...ghi
)) {
   print("$_ ", /$re/ ? "matches" : "doesn't match", "\n");
}
[download]

abcdefghi doesn't match
abc...ghi matches
[download]

#!/usr/bin/perl
use strict;
use warnings;

my $string = '\.foo';
print $string, "\n";

for (1..3) {
    $string = quotemeta $string;
    print $string, "\n";
}

__END__
# prints:
\.foo
\\\.foo
\\\\\\\.foo
\\\\\\\\\\\\\\\.foo
[download]

#!/usr/bin/perl
use strict;
use warnings;

my $string = '\.foo';

print $string, "\n";

for (1..3) {
    # Note the concatenation instead of re-quotemeta-ing
    $string .= quotemeta "*[$_]";
    print $string, "\n";
}


__END__
# prints:
\.foo
\.foo\*\[1\]
\.foo\*\[1\]\*\[2\]
\.foo\*\[1\]\*\[2\]\*\[3\]
[download]

In response to your updated question,

my $name = '(\w[\w-]*\w?)';       # any valid hostname segment
my $nnam = "(($name\\.)*$name)";  # one or more "name" segments

my %domainnames = (
  "$nname\\.com" => 'a commercial domain',
  "$nname\\.edu" => 'an educational institution',
);
[download]

is a solution. When quoting that with double quotes, you need to escape $ (unless you want interpolation), @ (unless you want interpolation), " and \ by preceeding them with \, so the regexp is $nname\.com would be "$nname\\.com" as a string literal.

But it's simpler to use qr/.../ (like I suggested in my earlier post):

my $name = qr/(\w[\w-]*\w?)/;      # any valid hostname segment
my $nnam = qr/(($name\.)*$name)/;  # one or more "name" segments

my %domainnames = (
  qr/$nname\.com/ => 'a commercial domain',
  qr/$nname\.edu/ => 'an educational institution',
);
[download]

However, it's a big waste to stringify a compiled regexp, so you might want to alter your structure for a major speed boost. I doubt you actually need a hash, so here's a solution using an array:

my $name = qr/(\w[\w-]*\w?)/;      # any valid hostname segment
my $nnam = qr/(($name\.)*$name)/;  # one or more "name" segments

my @domainnames = (
  { re => qr/$nname\.com/, desc => 'a commercial domain'        },
  { re => qr/$nname\.edu/, desc => 'an educational institution' },
);
[download]

If you really do need a hash:

Thanks very much, I think this is just what I needed. Just to make certain I understand what is going on,\ here, let me see if I can explain it to myself.

The qr// operator creates a compiled re from the string it is given, and this compiled re can be passed in a variable. However, because it is no longer a string (it is a special variable type??) any backslashes it originally contained are no longer subject to interpolation even when a string which contains it as a variable is itself contained in another string, and so on. Is that about right?

I also think you are right about using an array instead of a hash, particularly because I may want to add more fields to it.

Thanks again.

Sounds right. \ is interpretted at compile time in both cases. "..." returns a string with the slashes removed, and qr/.../ returns a compiled regexp (that stringifies to the slashed form, such as when used as a hash key).

Perhaps it will be easy to others, but right now I'm having a hard time wrapping my head around the question - perhaps a more concrete example exhibiting the problem could help me answer this.

 my $str1 = '???';
 my $str2 = '???';
 my $re = qr/$str1$str2/;
 # ...?
[download]