Re^2: Help in using arrays

Your code suggestion: while (<DATA>) { my $code = (split)[1]; for my $x (0..$#all) { if($code eq $all[$x]) { print $_; last; } } }
[download]
I suppose you have written it this way to stay close to the OP's coding style, but it should be mentioned that indexing the @all array is not necessary and not particularly perlish.

while (<DATA>) {
  my $code = (split)[1];
  for my $x ( @all ) {
    if($code eq $x) {
      print $_;
      last;
    }
  }
}
[download]

Now it becomes apparent that what the loop does is really a grep operation:

while (<DATA>) {
  my $code = (split)[1];
  print if grep $_ eq $code, @all;
  }
}
[download]

Finally, it turns out that grep can be replaced with a hash lookup when the list @all is replaced by a hash:

my %all =  map +( $_ => 1), qw(7723 7725 9908 7765 7874);
$all{ (split)[ 1]} and print while <DATA>;
[download]

Anno

Update: Stylistic change, pomposity tuned down a notch.

Comment on Re^2: Help in using arrays Select or Download Code

Replies are listed 'Best First'.
Re^3: Help in using arrays by davorg (Chancellor) on Mar 14, 2007 at 15:08 UTC
I agree with everything you say - and would almost certainly have said it too if I had had more time this morning :) Just one small point. At the point when you switch to using "grep", you lose the tiny optimisation that you get from using "last" in the loop. -- <http://dave.org.uk> "The first rule of Perl club is you do not talk about Perl club." -- Chip Salzenberg	[reply]
Re^4: Help in using arrays by Anno (Deacon) on Mar 14, 2007 at 15:13 UTC
Just one small point. At the point when you switch to using "grep", you lose the tiny optimisation that you get from using "last" in the loop. Indeed. I thought of mentioning it, but that seemed to invite a deviation to `List::Util::first` and I dropped the whole thing. Anno	[reply] [d/l]