The code seems very similar to your code in Searching and printing through a array - did my reply not work for you?

If you can tell me where my reply does not work for you I can maybe help you to adapt my code to your problem. It would also help to have a complete, self-contained program which initializes @all and reads the data from a __DATA__ section so we can run the code and reproduce the problem without any further setup on our part. Something like this:

#!/usr/bin/perl -w
use strict;

my @all = ("7723","7725","9908","7765","7874");

while (<DATA>) {
    # ... your code to check the current line
}:

__DATA__
77876    8543    CA84985    54E
77873    8003    CA84985    54E
77875    7725    CA84985    54E
...
[download]

If you are going to revisit a previous question then you should, at least, include a link to the earlier discussion so that we can see what advice has already been offered and ignored.

Update: I've now taken a closer look at your code and I can't see the problem that you are having. The code below is based on your code above and has been expanded to create a standalone program. It seems to work as expected and print out the whole line. I therefore suspect that your problem is in the bits of your code that you aren't showing us.

#!/usr/bin/perl

use strict;
use warnings;

my @all = qw(7723 7725 9908 7765 7874);

while (<DATA>) {
  for my $x (0..$#all) {
    if($_ =~ /$all[$x]/) {
      print $_;
    }
  }
}

__DATA__
77876    8543    CA84985    54E
77873    8003    CA84985    54E
77875    7725    CA84985    54E
77872    8511    CA84985    54E
77873    8123    CA84985    54E
77822    9908    CA84985    54E
77819    8503    CA84985    54E
77826    8040    CA84985    54E
77822    7874    CA84985    54E
77884    8543    CA84985    54E
77809    7211    CA84985    54E
[download]

And the output I get is:

77875    7725    CA84985    54E
77822    9908    CA84985    54E
77822    7874    CA84985    54E
[download]

There is, of course, a potential bug in this code as it checks for the existance of your numbers anywhere in a line of input and you specifically want to check for it in the second column. You can therefore change the central loop of my code to look lie this (and note that I've also been able to change the match operator to an equality operator).

while (<DATA>) {
  my $code = (split)[1];
  for my $x (0..$#all) {
    if($code eq $all[$x]) {
      print $_;
    }
  }
}
[download]

Finally, there's no point in checking for more than one match, so it's worth exiting the inner loop once a match is found.

while (<DATA>) {
  my $code = (split)[1];
  for my $x (0..$#all) {
    if($code eq $all[$x]) {
      print $_;
      last;
    }
  }
}
[download]

Your code suggestion:

while (<DATA>) {
  my $code = (split)[1];
  for my $x (0..$#all) {
    if($code eq $all[$x]) {
      print $_;
      last;
    }
  }
}
[download]

I suppose you have written it this way to stay close to the OP's coding style, but it should be mentioned that indexing the @all array is not necessary and not particularly perlish.

while (<DATA>) {
  my $code = (split)[1];
  for my $x ( @all ) {
    if($code eq $x) {
      print $_;
      last;
    }
  }
}
[download]

Now it becomes apparent that what the loop does is really a grep operation:

while (<DATA>) {
  my $code = (split)[1];
  print if grep $_ eq $code, @all;
  }
}
[download]

Finally, it turns out that grep can be replaced with a hash lookup when the list @all is replaced by a hash:

my %all =  map +( $_ => 1), qw(7723 7725 9908 7765 7874);
$all{ (split)[ 1]} and print while <DATA>;
[download]

Anno

Update: Stylistic change, pomposity tuned down a notch.

I agree with everything you say - and would almost certainly have said it too if I had had more time this morning :)

Just one small point. At the point when you switch to using "grep", you lose the tiny optimisation that you get from using "last" in the loop.

--


<http://dave.org.uk>

"The first rule of Perl club is you do not talk about Perl club." -- Chip Salzenberg

use strict;
use warnings;

my @wanted = qw{7723 7725 9908 7765 7874};
my $rxExtract;
{
    local $" = q{|};
    $rxExtract = qr{\b@wanted\b};
}

print
   map  { $_->[0] }
   grep { $_->[2] =~ $rxExtract }
   map  { [ $_, split ] }
   <DATA>;

__END__
77876    8543    CA84985    54E
77873    8003    CA84985    54E
77875    7725    CA84985    54E
77872    8511    CA84985    54E
77873    8123    CA84985    54E
77822    9908    CA84985    54E
77819    8503    CA84985    54E
77826    8040    CA84985    54E
77822    7874    CA84985    54E
77884    8543    CA84985    54E
77809    7211    CA84985    54E
[download]

The output is

77875    7725    CA84985    54E
77822    9908    CA84985    54E
77822    7874    CA84985    54E
[download]

I hope this is of use.

Cheers,

JohnGG

It seems to me like you're over-thinking your algorithm. What you want to express in code is "for each line of data, if the value in the second column is contained in my pre-existing dataset (@all), print the line". Perl is very expressive, so it allows you to say that almost directly:

#!/usr/bin/env perl
use strict; use warnings;

@all = ("7723","7725","9908","7765","7874");

while( <DATA> ) {
    my @column = split /\s+/;  #get columns out of data line
    for my $x (@all) {
      next unless $x == $column[1]; # compare second column, move on i
+f no match
      print $_;  # we found a match, print out the original line
      last;      # we're done, so stop comparing this line
    }
}

__DATA__
77876    8543    CA84985    54E
77873    8003    CA84985    54E
77875    7725    CA84985    54E
77872    8511    CA84985    54E
77873    8123    CA84985    54E
77822    9908    CA84985    54E
77819    8503    CA84985    54E
77826    8040    CA84985    54E
77822    7874    CA84985    54E
77884    8543    CA84985    54E
77809    7211    CA84985    54E
[download]

However, a knowledge of design patterns yields a more elegant solution suggested by the Schwartzian Transform.

#!/usr/bin/env perl
use strict; use warnings;

@all = ("7723","7725","9908","7765","7874");

# partial application of the Schwartzian Transform
# each unique value in @all will now be a key in the %all hash
my %all = map { $_ => 1 } @all;

while( <DATA> ) {
    my @column = split /\s+/;     #get columns out of data line
    print $_ if $all{$column[1]};
}

__DATA__
77876    8543    CA84985    54E
77873    8003    CA84985    54E
77875    7725    CA84985    54E
77872    8511    CA84985    54E
77873    8123    CA84985    54E
77822    9908    CA84985    54E
77819    8503    CA84985    54E
77826    8040    CA84985    54E
77822    7874    CA84985    54E
77884    8543    CA84985    54E
77809    7211    CA84985    54E
[download]

The transformation of array to hash allows the check to be very simple: "does our dataset contain this value?".