sub is_dos_format {
  local $_;

  ...
}

# or

sub is_dos_format {
  ...
  while (my $line = <RJA>) {
  ...
}
[download]

Anywho, here's the distilled example...

In addition to the other good suggestions you got (I hope not to repeat too many of them!) here are a few others:

my @files = ();
[download]

No need for the initialization and it doesn't add to clarity IMHO.

find(sub { $File::Find::name =~ m/${directory}(.*)$/; push @files, $1}
+,  $directory);
@files = grep { is_dos_format("$directory/$_") } @files;
[download]

Rather than collecting filenames in @files to process the latter with grep later, why don't you do so in the first place as files are being searched? If the files are many, then your program should be more responsive. Also, I don't understand the logic of stripping the base directory only to reinsert it later...

foreach my $file (@files) {
    print "FAILED FILE - $file\n";
}
[download]

Oh, and why another loop too?!? (grep is one in disguise: you're doing it twice when there's no logical reason to.)

        if ($_ =~ m/\r\n/) {
[download]

The whole point of the $_ pronoun is that it is the topicalizer: you either use an explicit variable name and the binding operator or just the match.

All in all I believe your code may be rewritten like:

#!/usr/bin/perl

use strict;
use warnings;
use File::Find;

my $directory = '/tmp/rja/find_test';

find { no_chdir => 1,
       wanted => sub {
           return unless -f;
           open my $fh, $_ or die "Can't open `$_': $!\n";
           my $file=$_;
           /\r\n/ and 
             print "FAILED FILE - $file\n" and return while <$fh>;
       } }, $directory;

__END__
[download]

• Use File::Spec->catfile for building the directory locations and pathnames
• Dont use constant open form, see open ( my $fh, $rw, $perm ) format
• I think reading in the whole file is probably better for whatever you want, on a modern system
• Don't grep for a file_path if the call requires it to be there

#!/usr/bin/perl -l
use strict;
use File::Find;
use File::Spec;

use constant DIRECTORY => '/tmp/rja/find_test';

my @files;

find( \&findsub, __PACKAGE__->DIRECTORY );

@files = grep is_dos_format($_), @files;

foreach my $file (@files) {
    print "FAILED FILE - $file";
}

sub findsub {
    push @files, $File::Find::name;
}

sub is_dos_format {
    my $abs_path = shift;

    open ( my $fh, '<', $abs_path )
        or die "open $abs_path: $!"
    ;

    if ( grep m/\r\n/s, <$fh> ) {
        return 1;
    }

    return undef;

}
[download]

I think reading in the whole file is probably better for whatever you want, on a modern system

I don't think so. It may not do a big difference, on a modern system. But under certain circumstances it may even there. After all he wants to quit searching as soon as /\r\n/ matches: what benefit would he have going on instead?

$ find /tmp/rja/find_test -type f -print0 |
  perl -0 -ne 'chomp;
  $t=do{local $/; open(T,"<",$_);<T>};
  print "$_ is completely CRLF\n" unless ( $t =~ /(?<!\r)\n/ )'
[download]

But then, I've never been a fan of File::Find, ever. It's just too weird and too slow.

BTW, are you looking for files that are completely CRLF, as I assumed in my snippet, or rather for files that have any CRLF in them? If the latter, the last part of the snippet would be  if ( $t =~ /\r\n/ ) update: and I'd change "is completely" to "has".