You should set up IO layers for STDOUT and $OUT, and never encode yourself:

binmode STDOUT, ':encoding(UTF-8)';

...

open my $OUT, '>:encoding(UTF-8)', "WE_EX2.out"
    or die "Can't open file WE_EX2.out for writing: $!";
[download]

But the real trouble is your call to utf8::encode, which prevents your regexes from matching.

Thank you - your help is greatly appreciated. I will incorporate your comments.

• X{1234}
  [download]

  should be

  \x{1234}      # \x{...}, not \X{...} or X{...}
  [download]

• /\X{1F00-1FE3}/
  [download]

  should be

  /[\x{1F00}-\x{1FE3}]/
  [download]

• utf8::encode($_[0]);
  [download]

  is just plain wrong.

So you end up with:

sub is_vowel {
    return $_[0] =~ /
        ^
        [\x{1F00}-\x{1FE3}\x{1FE6}-\x{1FFE}\x{0386}-\x{038F}\x{0390}\x
+{0391}\x{0395}\x{0397}\x{0399}\x{039F}\x{03A5}\x{03A9}\x{03AA}-\x{03B
+1}\x{03B5}\x{03B7}\x{03B9}\x{03BF}\x{03C5}\x{03C9}-\x{03CE}]
        \z
    /x;
}
[download]

There might be a better way of doing this, but i don't have time to research this right now.

sub is_vowel {
    return $_[0] =~ /
        ^
        [\x{1F00}-\x{1FE3}\x{1FE6}-\x{1FFE}\x{0386}-\x{038F}\x{0390}\x
+{0391}\x{0395}\x{0397}\x{0399}\x{039F}\x{03A5}\x{03A9}\x{03AA}-\x{03B
+1}\x{03B5}\x{03B7}\x{03B9}\x{03BF}\x{03C5}\x{03C9}-\x{03CE}]
        \z
    /x;
}
[download]

There might be a better way of doing this, but i don't have time to research this right now.

Ask me! Ask me! :)

First off, I would never use literal magic numbers like that. Let’s look at what that string really is:

[ἀ-ΰῦ-῾Ά-ΏΐΑΕΗΙΟΥΩΪ-αεηιουω-ώ]

Ew, gross! See where that is leading? And if that’s not a big enough hint, here are those as named characters:

\N{GREEK SMALL LETTER ALPHA WITH PSILI}-
\N{GREEK SMALL LETTER UPSILON WITH DIALYTIKA AND OXIA}
\N{GREEK SMALL LETTER UPSILON WITH PERISPOMENI}-
\N{GREEK DASIA}
\N{GREEK CAPITAL LETTER ALPHA WITH TONOS}-
\N{GREEK CAPITAL LETTER OMEGA WITH TONOS}
\N{GREEK SMALL LETTER IOTA WITH DIALYTIKA AND TONOS}
\N{GREEK CAPITAL LETTER ALPHA}
\N{GREEK CAPITAL LETTER EPSILON}
\N{GREEK CAPITAL LETTER ETA}
\N{GREEK CAPITAL LETTER IOTA}
\N{GREEK CAPITAL LETTER OMICRON}
\N{GREEK CAPITAL LETTER UPSILON}
\N{GREEK CAPITAL LETTER OMEGA}
\N{GREEK CAPITAL LETTER IOTA WITH DIALYTIKA}-
\N{GREEK SMALL LETTER ALPHA}
\N{GREEK SMALL LETTER EPSILON}
\N{GREEK SMALL LETTER ETA}
\N{GREEK SMALL LETTER IOTA}
\N{GREEK SMALL LETTER OMICRON}
\N{GREEK SMALL LETTER UPSILON}
\N{GREEK SMALL LETTER OMEGA}-
\N{GREEK SMALL LETTER OMEGA WITH TONOS}
[download]

So I think what needs to be done is that it needs to be reduced in normalization form D for canonical decomposition (which may introduce iotas because of the iota subscripts in Greek), and then after getting rid of marks and diacritics, some sort of pattern match comparison to only the 7 Greek vowels done.

To show you why you have to be more careful, here is an example of a phrase whose first word is all vowels, but which when rendered in upper‐, lower‐, and titlecase give very different looking results, because the number of code points changes under full case folding:

Lowercase

• ᾲ στο διάολο
• \x{1FB2} \x{3C3}\x{3C4}\x{3BF} \x{3B4}\x{3B9}\x{3AC}\x{3BF}\x{3BB}\x{3BF}

• \N{GREEK SMALL LETTER ALPHA WITH VARIA AND YPOGEGRAMMENI} \N{GREEK SMA
  +LL LETTER SIGMA}\N{GREEK SMALL LETTER TAU}\N{GREEK SMALL LETTER OMICR
  +ON} \N{GREEK SMALL LETTER DELTA}\N{GREEK SMALL LETTER IOTA}\N{GREEK S
  +MALL LETTER ALPHA WITH TONOS}\N{GREEK SMALL LETTER OMICRON}\N{GREEK S
  +MALL LETTER LAMDA}\N{GREEK SMALL LETTER OMICRON}
  [download]

Titlecase

• Ὰͅ Στο Διάολο
• \x{1FBA}\x{345} \x{3A3}\x{3C4}\x{3BF} \x{394}\x{3B9}\x{3AC}\x{3BF}\x{3BB}\x{3BF}

• \N{GREEK CAPITAL LETTER ALPHA WITH VARIA}\N{COMBINING GREEK YPOGEGRAMM
  +ENI} \N{GREEK CAPITAL LETTER SIGMA}\N{GREEK SMALL LETTER TAU}\N{GREEK
  + SMALL LETTER OMICRON} \N{GREEK CAPITAL LETTER DELTA}\N{GREEK SMALL L
  +ETTER IOTA}\N{GREEK SMALL LETTER ALPHA WITH TONOS}\N{GREEK SMALL LETT
  +ER OMICRON}\N{GREEK SMALL LETTER LAMDA}\N{GREEK SMALL LETTER OMICRON}
  [download]

Uppercase

• ᾺΙ ΣΤΟ ΔΙΆΟΛΟ
• \x{1FBA}\x{399} \x{3A3}\x{3A4}\x{39F} \x{394}\x{399}\x{386}\x{39F}\x{39B}\x{39F}

• \N{GREEK CAPITAL LETTER ALPHA WITH VARIA}\N{GREEK CAPITAL LETTER IOTA}
  + \N{GREEK CAPITAL LETTER SIGMA}\N{GREEK CAPITAL LETTER TAU}\N{GREEK C
  +APITAL LETTER OMICRON} \N{GREEK CAPITAL LETTER DELTA}\N{GREEK CAPITAL
  + LETTER IOTA}\N{GREEK CAPITAL LETTER ALPHA WITH TONOS}\N{GREEK CAPITA
  +L LETTER OMICRON}\N{GREEK CAPITAL LETTER LAMDA}\N{GREEK CAPITAL LETTE
  +R OMICRON}
  [download]

So here’s probably how I’d do it, since I prefer to be able to read the code:

use utf8;
use strict;
use warnings;

use Unicode::Normalize qw(NFD);

sub is_greek_vocalic($) {
    die "wrong args" unless @_ == 1;
    local $_ = NFD(lc(shift()));
    s/\p{Mark}+//g;       # combining marks from NFD form
    s/\p{Diacritic}+//g;  # eg, GREEK DASIA, which is \p{Sk}
    return scalar m{ ^ [αεηιουω] + \z }x;
}

But if you want to use named characters, it would look more like this:

use Unicode::Normalize qw(NFD);

sub is_greek_vocalic($) {
    use charnames "greek";
    die "wrong args" unless @_ == 1;
    local $_ = NFD(lc(shift()));
    s/\pM+//g;            # combining marks from NFD form
    s/\p{Diacritic}+//g;  # eg, GREEK DASIA, which is \p{Sk}
    return scalar m{
        ^
        [\N{alpha}\N{epsilon}\N{eta}\N{iota}\N{omicron}\N{upsilon}\N{o
+mega}]+
        \z
    }x; 
}
[download]

Doesn’t that look better now?

Much better, thanks!

Two recommendations -- neither of which goes to your current issue (answered well, above), but which may be important in some other context:

IMO (Caveat: my O is neither definitive nor authoritative), you rely too much on the default var, $_. Doing so, in the face of possible future needs for tweaking, extension, modification, or refactoring of your code can
  a) create a script-version that inadvertently replaces the content of $_ with something other than its current content... and
  b) make - for yourself or some future programmer - a head-scratcher about what's supposed to be in $_, once you're reading some lines down.

Changing your code (and code-writing practices) to use explicitly named vars for values you're passing around, hither-and-thither, is relatively low overhead -- while writing and when executing. For example, one could do this (your line numbers, my comments):

056: my (@words, $char, $vowel);
057: while (<$IN>) { 
058:     @words = split /[\W]/, ;
059:     for my $word(@words) {                         ## explicit va
+riable declared...
060:         print $OUT (encode ('UTF-8', $word)) . "\n";  ## and put 
+to further use...
061:         my $count = 0;
061a-061z:                              ## hypothetical insert, tweak,
+ extension, etc
062:         my $end = length($word);                   ## Ahah, easy 
+to verify that 
                                                       ## we're gettin
+g word length
063:         for (my $i = 0; $i < $end; $i++) {
064:             $char = substr($word, $i, 1);          ## and again..
+..
[download]

I also recommend that you consider advice seen often here; that you eschew using the &foo... form of sub call which precedes the sub name with an ampersand... unless you know * EXACTLY * why you need the ampersand. Summarizing that advice: "Don't, because using the ampersand when not needed can help you create bugs that are very hard to find... and because it probably doesn't do what you think it does."

Here's some additional reading:

• First, a canonical resource: Learning Perl - However, this links to 3rd Ed; you should use 5th edition, but 3rd is freely available on line; see {search for} "Omitting the Ampersand"
• Perl-Critic http://search.cpan.org/dist/Perl-Critic/lib/Perl/Critic/Policy/Subroutines/ProhibitAmpersandSigils.pm chimes in with this "description: 'Since Perl 5, the ampersand sigil is completely optional when invoking subroutines. It also turns off checking of subroutine prototypes. It's easily confused with the bitwise 'and' operator.'"
• https://www.socialtext.net/perl5/subroutines_called_with_the_ampersand -- Seems to me to be an excellent discussion (don't let the https: dismay you; it's openly readable)
• http://www.webreference.com/programming/perl/subroutines/ - don't stop reading after the first couple para: the meat re "&foo()" is well down in the text.
• Re: What is the point of the & sigil for function refs? - 6 years old, but still relevant for any 5.n version ...
• http://www.0x61.com/forum/programming-perl-f240/ampersand-subroutine-t1136804.html -- ...and there are a few worthy points in this thread
• http://www.devdaily.com/perl/call-perl-subroutines-sub-function-ampersand - an interesting perspective