For simple problems I usually use something like this:

{
  my @p; BEGIN { @p = (2, 3) } 
  sub nextprime { 
    my $p = $p[$#p];
    DIV: while (1) {
      $p += 2; 
      my $pc = 0;
      while (1) { 
        my $d = $p[$pc++];
        last if $d * $d > $p;
        next DIV unless $p % $d;
      }
      $p[@p] = $p; 
      return $p;
    }
  }

  sub factors { 
    my $n = shift;
    my($pc, @result) = (0);
    while ($n > 1) {
      my $d = $p[$pc++] || nextprime();
      if ($d * $d > $n) { 
        push @result, $n;
        $n = 1;
      } else {
        while ($n % $d == 0) {
          $n /= $d;
          push @result, $d;
        }
      }
    }
    \@result;
  }
}
[download]

The rest of the time I use Math::Big*, sometimes with Pari or (lately) GMP.

Hugo

Nice, thankyou. I like nextPrime(). I was kludging something together by embedding the first 1000 primes in a DATA section.

---

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

Lingua non convalesco, consenesco et abolesco. -- Rule 1 has a caveat! -- Who broke the cabal?

"Science is about questioning the status quo. Questioning authority".

The "good enough" maybe good enough for the now, and perfection maybe unobtainable, but that should not preclude us from striving for perfection, when time, circumstance or desire allow.

I don't suppose you know of a good factoring algorithm?

From the future: these days, Math::Prime::Util (along with Math::Prime::Util::GMP for larger inputs) is excellent.