A Small XML::Parser issue

siva kumar has asked for the wisdom of the Perl Monks concerning the following question:

I have huge xml file. I have given below the part of problem area code.
The part of my xml data looks like this ..

<Company_Name>XYZ CMPNY</Company_Name><ArgId>775340</ArgId><First_Name
+>Carol &amp; Jerry</First_Name>
[download]

I need only "Company_Name" and "First_Name". I have written perl code using XML::Parser. The code below

use strict;
use XML::Parser;
my $parser = new XML::Parser(ErrorContext => 2);

my $xmlStr = "<data>
<Company_Name>XYZ CMPNY</Company_Name> 
<ArgId>775340</ArgId>
<First_Name>Carol &amp; Jerry</First_Name>
</data>";

my $writeDataFlag = 0;

$parser->setHandlers( 
      Start => \&start_handler,
      Char => \&char_handler,
       End => \&end_handler);

$parser->parse($xmlStr);


sub char_handler
{
   my ($p, $data) = @_;
      if($writeDataFlag ==1 ){
         print "Data - [$data] \n";
      }
}

sub start_handler
{

   my ($p, $data) = @_;
   if($data =~ /^(Company_Name|First_Name)$/) {
         $writeDataFlag = 1;
   }
}

sub end_handler
{
my ($p, $data) = @_;
   $writeDataFlag = 0;
}

1;
[download]

OUTPUT:

Company_Name ---> [XYZ CMPNY]
First_Name ---> [Carol ]
[&]
[ Jerry]
[download]

I need OTUPUT:

Company_Name ---> [XYZ CMPNY]
First_Name ---> [Carol & Jerry]
[download]

Please suggest me whats wrong with my code?
Thanks Sivakumar

Comment on A Small XML::Parser issue Select or Download Code

Replies are listed 'Best First'.

Re: A Small XML::Parser issue
by davorg (Chancellor) on Feb 16, 2007 at 12:34 UTC

The documentation for the Char handler says this:

A single non-markup sequence of characters may generate multiple calls to this handler

So you need to accumulate the data and only print it in the end handler. Something like this perhaps:

use strict;
use XML::Parser;
my $parser = new XML::Parser(ErrorContext => 2);

my $xmlStr = "<data>
<Company_Name>XYZ CMPNY</Company_Name>
<ArgId>775340</ArgId>
<First_Name>Carol &amp; Jerry</First_Name>
</data>";

my $writeDataFlag = 0;

$parser->setHandlers(
   Start => \&start_handler,
   Char => \&char_handler,
   End => \&end_handler);

$parser->parse($xmlStr);

my $text;

sub char_handler {
  my ($p, $data) = @_;
  if ($writeDataFlag) {
    $text .= $data;
  }
}

sub start_handler {
  my ($p, $data) = @_;
  if($data =~ /^(Company_Name|First_Name)$/) {
    $writeDataFlag = 1;
  }
}

sub end_handler {
  my ($p, $data) = @_;
  if ($writeDataFlag) {
    print "Data - [$text] \n";
    $text = '';
    $writeDataFlag = 0;
  }
}
[download]

<http://dave.org.uk>

"The first rule of Perl club is you do not talk about Perl club." -- Chip Salzenberg

[reply]
[d/l]

Re^2: A Small XML::Parser issue

by siva kumar (Pilgrim) on Feb 16, 2007 at 12:47 UTC

[reply]

Re: A Small XML::Parser issue
by fmerges (Chaplain) on Feb 16, 2007 at 12:27 UTC

Hi,

Take a look at XML::Twig or XML::TreeBuilder.

Update: see here to see an example by GrandFather

Regards,

fmerges at irc.freenode.net

[reply]

Re: A Small XML::Parser issue
by Jenda (Abbot) on Feb 16, 2007 at 19:35 UTC

I know I'm getting annoying

use XML::Rules;

my $parser = XML::Rules->new(
 rules => [
  _default => '',
  'Company_Name,First_Name' => sub {
   print "$_[0] ---> [$_[1]->{_content}]\n";
   return;
  },
 ]
);

my $xmlStr = "<data>
<Company_Name>XYZ CMPNY</Company_Name> 
<ArgId>775340</ArgId>
<First_Name>Carol &amp; Jerry</First_Name>
</data>";

$parser->parse($xmlStr);
[download]

Jenda
Support Denmark!
Defend the free world!

[reply]
[d/l]


Clear questions and runnable code get the best and fastest answer
	PerlMonks