#!/usr/bin/perl
use strict;
use warnings;
while (<DATA>) {
    chomp;
    my @col = split /;/;
    push @col, '' for @col .. 2;
    print join ';', @col;
    print "\n";
}
__DATA__
a;3
b;2;3
c;5;4
d;6
[download]

Update: As noted by tye in the CB, this solution was originally not tested. I added chomp and changed @col .. 3; to @col .. 2;

You get a similar solution using a very useful idiom if you replace

my @col = split /;/;
push @col, '' for @col .. 2;
print join ';', @col;
[download]

with

my $len = 3;
print join ';', (split(/;/), ('') x $len)[0 .. $len-1];
[download]

assuming that there are at most two semi-colons in the string. The focus here is the way to create the default trailing elements. This is quite useful when you create hashes, where it's imperative to not have any missing (or extra) elements. For instance:

my %foo =
  map { (split /:/, $_, 2)[0, 1] } # Implicit "default" undef.
  qw/
    foo:bar
    baz
    zip:zap:zoom
  /
;

use Data::Dumper;
print Dumper(\%foo);

__END__
$VAR1 = {
          'baz' => undef,
          'foo' => 'bar',
          'zip' => 'zap:zoom'
        };
[download]

A naive

my %foo = map { split /:/ } ...;
[download]

would've been disastrous.

lodin

use strict;
use warnings;

print
   map
   {
       qq{@{ [
          join
             q{;},
             @{ $_ } == 3
             ? ( @{ $_ } )
             : ( @{ $_ }, ( q{} ) x ( 3 - @{ $_ } ) ) ]
       }\n}
   }
   map { chomp; [ split m{;} ] }
   <DATA>;

__END__
a;3
b;2;3
c;5;4
d;6

f
[download]

The output.

a;3;
b;2;3
c;5;4
d;6;
;;
f;;
[download]

I hope this is useful.

Cheers,

JohnGG

#!/usr/bin/perl
use strict;
use warnings;

map { print if s/\A (\w;\d) (?!;\d) / $1; /xms } <DATA>;



__DATA__
a;3
b;2;3
c;5;4
d;6
[download]

Output :
a;3;
d;6;
[download]

map { print ... }

That's worth at least two fifteen-yard penalties right there! I'm sort of horrified and impressed.

It's for error checking, of course

any { !$_ } map { print ... } ...
   and die;
[download]

;)

$ echo "a;3
b;2;3
c;5;4
d;6" | perl -pe'y/;//==1&&s/$/;/'
a;3;
b;2;3
c;5;4
d;6;
[download]

I went beyond the spec, and padded lines with no semi-colons too...

perl -e 's^$^";"x(2-y-;--)^e' -p data
[download]

---
my name's not Keith, and I'm not reasonable.