shift, undef and 'or die'

agoth has asked for the wisdom of the Perl Monks concerning the following question:

I'm trying to test for a parameter with shift or die.
The parameter in this case is zero, so I am wary of dodgy true/false interpretations on my part. However, with @_ being three items long, shift populates the variable it is supposed to and then dies as well.

Why?
Is it because shift is returning zero which is evaluating to false? I was expecting shift to return success if it could shift an item.
Is there an alternative operator I could use or some conbination of shift / defined?

#!/usr/local/bin/perl -w
use strict;

lookup(22);
lookup(22, 'data');

my $var = 111;
lookup(22, 'data', $var);

$var = 0;
lookup(22, 'data', $var);
sub lookup {
    print "Num params", scalar (@_), "\n";

    my $self      = shift;
    my $data_type = shift or print "type not provided ConfReaderlookup
+\n";
    my $item      = shift or print "item not provided ConfReaderlookup
+\n";

    print "ITEM isnt in here actually\n" unless defined $item;
    print "----------------------------\n";
}
[download]

Comment on shift, undef and 'or die' Download Code

Replies are listed 'Best First'.
Re: shift, undef and 'or die' by arturo (Vicar) on Jul 26, 2001 at 18:01 UTC
`shift` returns the value of the first entry in the array (or `undef` if there's nothing left in the array). So your surmise is right, if it's 0 it evaluates to false. use some variant on `my $data_type; print $errmsg unless defined ($data_type = shift);` to get the behavior you want. update even that may not be totally correct; `undef` is a valid value for an entry in an array which may have more members -- the fact that `shift` returns `undef` does not guarantee that you've hit the end of the array -- so you may want to check both the size of the argument array and the definedness of its members, if your purposes require that. HTH. `perl -e 'print "How sweet does a rose smell? "; chomp ($n = <STDIN>); +$rose = "smells sweet to degree $n"; other_name = rose; print "$oth +er_name\n"'` [download]	[reply] [d/l] [select]
Re: shift, undef and 'or die' by tadman (Prior) on Jul 26, 2001 at 18:15 UTC
As arturo is suggesting, it might be more prudent to check parameters using defined rather than simple boolean math. It is more practical, as well, since you can really go to town: `sub lookup { my $self = shift; my ($data_type,$item) = @_; warn "data_type not provided\n" unless (defined $data_type); warn "item not provided\n" unless (defined $item); # ... }` [download]	[reply] [d/l]
Re: shift, undef and 'or die' by dragonchild (Archbishop) on Jul 26, 2001 at 18:07 UTC
Is it because shift is returning zero which is evaluating to false? The short answer is "Yes". Shift returns what it shifts, not a success. Think about it this way - it can only really return one thing. To do this, you have to push it to a temp then do a trinary checking on defined-ness.	[reply]
(tye)Re: shift, undef and 'or die' by tye (Sage) on Jul 26, 2001 at 20:18 UTC
`die "Type not provided" unless @_; my $data_type= shift(@_);` [download] Is probably how I'd do it (though there are certainly other ways). (: - tye (but my friends call me "Tye")	[reply] [d/l]
Re: shift, undef and 'or die' by ariels (Curate) on Jul 26, 2001 at 18:29 UTC
Use the lvalue returned from the assignment, and test it for definedness: `sub foo { defined(my $x = shift) or warn "No parameter given!" # ... }` [download] Of course, it still can't tell if the array was empty or if it shifted an undefined value off it.	[reply] [d/l]


go ahead... be a heretic
	PerlMonks